gnome-extra/gnome-browser-connector: Version bump to 42.1

Signed-off-by: Yuri Konotopov <ykonotopov@gnome.org>
Signed-off-by: Matt Turner <mattst88@gentoo.org>

1 files changed, 47 insertions, 0 deletions

diff --git a/gnome-extra/gnome-browser-connector/gnome-browser-connector-42.1.ebuild b/gnome-extra/gnome-browser-connector/gnome-browser-connector-42.1.ebuild
new file mode 100644
index 000000000000..6b5b05530200
--- /dev/null
+++ b/gnome-extra/gnome-browser-connector/gnome-browser-connector-42.1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit gnome.org meson python-single-r1 xdg
+
+DESCRIPTION="OS-native connector counterpart for GNOME Shell browser extension"
+HOMEPAGE="https://wiki.gnome.org/Projects/GnomeShellIntegration"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}
+	$(python_gen_cond_dep 'dev-python/pygobject:3[${PYTHON_USEDEP}]')
+"
+RDEPEND="${DEPEND}
+	gnome-base/gnome-shell
+"
+
+src_install() {
+	meson_src_install
+	python_fix_shebang "${D}/usr/bin/${PN}"
+	python_fix_shebang "${D}/usr/bin/${PN}-host"
+	python_optimize
+
+	if [[ $(get_libdir) != "lib" && "${SYMLINK_LIB}" != yes ]]; then
+		# Workaround www-client/firefox-bin manifests location
+		# Bug: https://bugs.gentoo.org/643522
+		insinto /usr/lib/mozilla/native-messaging-hosts
+		for id in chrome_gnome_shell browser_connector; do
+			doins "${ED}/usr/$(get_libdir)/mozilla/native-messaging-hosts/org.gnome.${id}.json"
+		done
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	elog "Please note that this package provides OS-native connector only."
+	elog "You can install browser extension using link provided at"
+	elog "https://extensions.gnome.org website."
+}