gnome-extra/gnome-software: Bump to 46.4

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/37961
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

2 files changed, 112 insertions, 0 deletions

diff --git a/gnome-extra/gnome-software/Manifest b/gnome-extra/gnome-software/Manifest
index 3ab0f0c8d146..3d1719cc4cd3 100644
--- a/gnome-extra/gnome-software/Manifest
+++ b/gnome-extra/gnome-software/Manifest
@@ -1,3 +1,4 @@
 DIST gnome-software-45.3.tar.xz 2477736 BLAKE2B 82a12e4d22e28c6c6345ae654f97911cdfeeff658dc3fbea68df949856c4552520edc6fc5f67d19fcfd85af88eb6d285561ddc294938ce753ffbc05a8b703398 SHA512 45c8c92c9bd046b37b3fb4e817a0ea83fe9323d019f86140357f90bb2a0bf9dda5d33798c4b4d78303e2402c6cb603a4ff467e260e734b7ba97f07ebfaf4044c
 DIST gnome-software-46.2.tar.xz 2574280 BLAKE2B 30ad2dfeebc1477f9917604eb5749f45b04770322de5660fe8661ea4df4df2699854f2fcc18349ba54c62a9af2c0a47e070f152e88b9bffece40f8e6d5be6ef2 SHA512 4e7cccc20001ccee114508bb50e2a25968ee6fea64fb545e1174ff435cd368b2d7c928b6a182874af8e9f0c99f9f506e75c5ac9bf61b35ba0a897368ae0abc3c
 DIST gnome-software-46.3.tar.xz 2574916 BLAKE2B 017ef6b463a103b87e3935ba236179ecba2e4530c65986bbe6451109122e2ad02715bf12d0cff4459ef2211a3debd1d4dfb566e295e4ade4e93096bae308b982 SHA512 dae91ae3fa9737bf496623663e709b6251ec1390692ab34f556c2cf8efbfb330e45a9824c93c62e37a2f673bec42e9a09025ae69b8e3cb1d942ec8574e04c51c
+DIST gnome-software-46.4.tar.xz 2575200 BLAKE2B bc5af24e0b71f279c26b83c3808bb5ee4e41d405d9a5370f7f37b3f19aab0043b338a1f3212ad74e6cfe02794ec16ec88b222322eb27190c0863a0ac5b88b3fa SHA512 148cdb3d3b3b0d74e00adcc066cf85fc20f86d9196def5132dfbb7b579464abe12c199d7f45b289d980ea634ddbce677be7588e2600a5f08ccd4630276a78799
diff --git a/gnome-extra/gnome-software/gnome-software-46.4.ebuild b/gnome-extra/gnome-software/gnome-software-46.4.ebuild
new file mode 100644
index 000000000000..fc51a767d046
--- /dev/null
+++ b/gnome-extra/gnome-software/gnome-software-46.4.ebuild
@@ -0,0 +1,111 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson virtualx xdg
+
+DESCRIPTION="Gnome install & update software"
+HOMEPAGE="https://apps.gnome.org/Software"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~loong ~x86"
+IUSE="flatpak +firmware gnome gtk-doc sysprof udev snap test"
+
+RDEPEND="
+	>=dev-libs/appstream-0.14.0:0=
+	>=x11-libs/gdk-pixbuf-2.32.0:2
+	>=dev-libs/libxmlb-0.1.7:=
+	>=gui-libs/gtk-4.12.0:4
+	>=dev-libs/glib-2.70.0:2
+	>=dev-libs/json-glib-1.6.0
+	>=net-libs/libsoup-3.0:3.0
+	>=gui-libs/libadwaita-1.4.0:1
+	sysprof? ( >=dev-util/sysprof-capture-3.40.1:4 )
+	gnome? ( >=gnome-base/gsettings-desktop-schemas-3.18.0 )
+	sys-auth/polkit
+	firmware? ( >=sys-apps/fwupd-1.6.2 )
+	flatpak? (
+		>=sys-apps/flatpak-1.14.0-r1
+		dev-util/ostree
+	)
+	snap? (
+		app-containers/snapd
+		sys-libs/snapd-glib:=
+	)
+	udev? ( dev-libs/libgudev )
+	>=gnome-base/gsettings-desktop-schemas-3.11.5
+"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/libglib-testing )
+"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? (
+		dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3
+	)
+"
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	sed -i -e '/install_data.*README\.md.*share\/doc\/gnome-software/d' meson.build || die
+	# We don't need language packs download support, and it fails tests in 3.34.2 for us (if they are enabled)
+	sed -i -e '/subdir.*fedora-langpacks/d' plugins/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use test tests)
+		$(meson_feature gnome gsettings_desktop_schemas) # Honoring of GNOME date format settings.
+		-Dman=true
+		-Dpackagekit=false
+		# -Dpackagekit_autoremove
+		-Dpolkit=true
+		-Deos_updater=false # Endless OS updater
+		$(meson_use firmware fwupd)
+		$(meson_use flatpak)
+		-Dmalcontent=false
+		-Drpm_ostree=false
+		-Dwebapps=true
+		-Dhardcoded_foss_webapps=true
+		-Dhardcoded_proprietary_webapps=true
+		$(meson_use udev gudev)
+		-Dapt=false
+		$(meson_use snap)
+		-Dexternal_appstream=false
+		$(meson_use gtk-doc gtk_doc)
+		-Dhardcoded_curated=true
+		# TODO: Will this be beneficial to us with flatpak at least? If
+		# enabled, it shows some apps under installed (probably merely due to
+		# /usr/share/app-info presence), but launching and removal of them is
+		# broken
+		-Ddefault_featured_apps=false
+		-Dmogwai=false #TODO?
+		$(meson_feature sysprof)
+		-Dprofile=''
+		-Dsoup2=false
+		-Dopensuse-distro-upgrade=false
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx dbus-run-session meson test -C "${BUILD_DIR}" || die
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}