kde-apps/cantor: 23.04.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 112 insertions, 0 deletions

diff --git a/kde-apps/cantor/Manifest b/kde-apps/cantor/Manifest
index c413db8e1624..412a19ef1a4f 100644
--- a/kde-apps/cantor/Manifest
+++ b/kde-apps/cantor/Manifest
@@ -1 +1,2 @@
 DIST cantor-22.12.3.tar.xz 9251596 BLAKE2B 44b67f6683a1e0ca03dc85999b8cde72851a57e4373e6fe8c2b4cc069062b07e9d6f7bc1869507433f3ce2c05b4ba033e4e536f555ef0ad4d022ab164ba0944a SHA512 c90ae7e18f768fc9f758fb855b7cab84bbacbf3d61b5d8eacd5b408f5eb76837711c7ae356fb11637edb9eac96f4b260c1d14302a4eaabdcd17e098fe9d8247e
+DIST cantor-23.04.0.tar.xz 9266376 BLAKE2B 34d7e13bbc2a01e1eba613ad9303bb9e933984e35959502bc1e128bcec2ec071bf649c5697eb0a45181c1f6c2081cd207576af2b8ff01fa28c0937b95a7a1fbd SHA512 755ed10f213ef9eec8f2f43e5719a62aefe692c63fef1234dbcc680c25d3d5af1cbbfde523ce7392d4a77bbaebbdd27912b611789cfcf14d1c4138317f5ad8cf
diff --git a/kde-apps/cantor/cantor-23.04.0.ebuild b/kde-apps/cantor/cantor-23.04.0.ebuild
new file mode 100644
index 000000000000..3b61cae27fe7
--- /dev/null
+++ b/kde-apps/cantor/cantor-23.04.0.ebuild
@@ -0,0 +1,111 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_MAKEFILE_GENERATOR="emake"
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="forceoptional"
+LUA_COMPAT=( luajit )
+PYTHON_COMPAT=( python3_{9..11} )
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.104.0
+QTMIN=5.15.5
+inherit ecm gear.kde.org lua-single optfeature python-single-r1
+
+DESCRIPTION="Interface for doing mathematics and scientific computing"
+HOMEPAGE="https://apps.kde.org/cantor/ https://edu.kde.org/cantor/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+analitza julia lua postscript python qalculate R"
+
+REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} ) python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="test"
+
+# TODO Add Sage Mathematics Software backend (https://www.sagemath.org)
+DEPEND="
+	app-text/poppler[qt5]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qthelp-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwebengine-${QTMIN}:5[widgets]
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=dev-qt/qtxmlpatterns-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kpty-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/syntax-highlighting-${KFMIN}:5
+	analitza? ( >=kde-apps/analitza-${PVCUT}:5 )
+	julia? ( dev-lang/julia )
+	lua? ( ${LUA_DEPS} )
+	qalculate? (
+		sci-libs/cln
+		sci-libs/libqalculate:=
+	)
+	postscript? ( app-text/libspectre )
+	python? (
+		${PYTHON_DEPS}
+		>=dev-qt/qtdbus-${QTMIN}:5
+	)
+	R? ( dev-lang/R )
+"
+RDEPEND="${DEPEND}
+	!analitza? ( !julia? ( !lua? ( !python? ( !qalculate? ( !R? (
+		|| (
+			sci-mathematics/maxima
+			sci-mathematics/octave
+		)
+	) ) ) ) ) )
+"
+BDEPEND="x11-misc/shared-mime-info"
+
+pkg_setup() {
+	use lua && lua-single_pkg_setup
+	use python && python-single-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_configure() {
+	use julia && addpredict /proc/self/mem # bug 602894
+
+	local mycmakeargs=(
+		$(cmake_use_find_package analitza Analitza5)
+		$(cmake_use_find_package julia Julia)
+		$(cmake_use_find_package lua LuaJIT)
+		-DUSE_LIBSPECTRE=$(usex postscript)
+		$(cmake_use_find_package python Python3)
+		$(cmake_use_find_package qalculate Qalculate)
+		$(cmake_use_find_package R R)
+	)
+	use lua && mycmakeargs+=(
+		-DLUAJIT_INCLUDEDIR="${EPREFIX}/$(lua_get_include_dir)"
+		-DLUAJIT_LIBDIR="${EPREFIX}/$(lua_get_cmod_dir)"
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "Maxima backend" sci-mathematics/maxima
+		optfeature "Octave backend" sci-mathematics/octave
+		optfeature "LaTeX support" virtual/latex-base
+	fi
+	ecm_pkg_postinst
+}