kde-apps/spectacle: 21.08.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 72 insertions, 0 deletions

diff --git a/kde-apps/spectacle/Manifest b/kde-apps/spectacle/Manifest
index 31c906281a33..d4018f024c40 100644
--- a/kde-apps/spectacle/Manifest
+++ b/kde-apps/spectacle/Manifest
@@ -1,2 +1,3 @@
 DIST spectacle-21.04.3.tar.xz 1175024 BLAKE2B 00d5ca9bf905b889e1ebbd510efc7d86571533e53206c5c65130d8b018d9e1941e283b698baab497928c6e3255d067ae6b4fde279945c0d56ed7ab7e9f226e83 SHA512 86af85d322c8d1231c4c47edaf886077dcfd1b20a33d6022ef5a8a543261e3d9f8c7b33957140d32f346c3dbaa87e13c9bed25b391771185468b4994e7ca3841
 DIST spectacle-21.08.0.tar.xz 1213020 BLAKE2B 3b485ffa67c699a9384f7d9444e945a64cfaf03fd7b14f47610cf81b12125c7ca63a75280e80243898f223f939c5edfee02ef674ab39cb0fe25f97737e066cb0 SHA512 326a99fc176140d98763e3981cb2f87a44915ae5ef5a3110d6139ba7df96117a4d65f72dcc8d24bdb261e842b5a256a24ff8b281c518d953170964e425fd3134
+DIST spectacle-21.08.1.tar.xz 1213424 BLAKE2B 34f2792a160173257b1cd747bbe8e6f642de0538b1d1113a10df00efb0f9aeb78ffc2293c78251036a7eb004e72f307e12a319ccf733c3f6172352bbb96aa439 SHA512 7ae7d3ca3239a0cc8abaa355dafee9f1185ae52e86f5c657e7d692219d5d2cee6e5072ce71af9c0acfabe6b023f9e3d8bddacf6ab82b8fa14d5096f1b708565e
diff --git a/kde-apps/spectacle/spectacle-21.08.1.ebuild b/kde-apps/spectacle/spectacle-21.08.1.ebuild
new file mode 100644
index 000000000000..c2a88f8e43f4
--- /dev/null
+++ b/kde-apps/spectacle/spectacle-21.08.1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="forceoptional"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.84.0
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Screenshot capture utility"
+HOMEPAGE="https://apps.kde.org/spectacle/"
+
+LICENSE="LGPL-2+ handbook? ( FDL-1.3 ) kipi? ( GPL-2+ )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="+annotate kipi share"
+
+# TODO: Qt5Svg leaking from media-libs/kimageannotator
+DEPEND="
+	>=dev-qt/qdbus-${QTMIN}:5
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwayland-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	x11-libs/libxcb
+	x11-libs/xcb-util
+	x11-libs/xcb-util-cursor
+	x11-libs/xcb-util-image
+	annotate? ( >=media-libs/kimageannotator-0.5.0 )
+	kipi? ( >=kde-apps/libkipi-${PVCUT}:5= )
+	share? ( >=kde-frameworks/purpose-${KFMIN}:5 )
+"
+RDEPEND="${DEPEND}
+	kipi? ( >=kde-apps/kipi-plugins-${PVCUT}:5 )
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# Unnecessary with >=media-libs/kimageannotator-0.4.0
+	sed -e "/find_package\s*(\s*X11/d" -e "/find_package\s*(\s*kColorPicker/d" \
+		-i CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package annotate kImageAnnotator)
+		$(cmake_use_find_package kipi KF5Kipi)
+		$(cmake_use_find_package share KF5Purpose)
+	)
+	ecm_src_configure
+}