kde-frameworks/plasma: 5.101.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 73 insertions, 0 deletions

diff --git a/kde-frameworks/plasma/Manifest b/kde-frameworks/plasma/Manifest
index 2fa718fa26f5..20f34a0fd2d7 100644
--- a/kde-frameworks/plasma/Manifest
+++ b/kde-frameworks/plasma/Manifest
@@ -1,2 +1,3 @@
 DIST plasma-framework-5.100.0.tar.xz 3302260 BLAKE2B 7b928023475502184b9c9d804b34584e278402692a2c3a39246598618f2ee4f2780b0ebed769a4c891e6a51d82f3beb359a60814f7a3fc351df22bbfab17669b SHA512 65d52ceb6454cf3b9a1d898eb8bbd65c96d9eabaf4a0213bf72ee4b9decb0a3cf20e251140186ad96d7346e64533320fee1b8b7157d0a3260e4f4ed0aa1abdac
+DIST plasma-framework-5.101.0.tar.xz 3303508 BLAKE2B e951f30e69cf979cde50fc46dbd197ee92d53875532efc3146bd421d121ba37bfed2f520a2b18afd0cb8a932b5738671049a25a312b762644bc2825a300b9cb9 SHA512 c1bd66810213634d533e7d63d256c57a923f0d26c2bdcca17ab29be46664bc3bfa578b739c89b3cf429bda10cf6a71ec8cc1ec60a554273719e9b6e041dcdad5
 DIST plasma-framework-5.99.0.tar.xz 3141664 BLAKE2B b37534440bc1f3d8f5fc13b6b62527c1bdde4b5d5d1c88530c49da2be221c9f55afac832cd8db61eb1bb91328145bc9b4c9e7b227b1ce740b10fa1bbefd3d2ef SHA512 bcf4f33facb20b542a90f5216fc0c5778d4de51d6a0ae86abdd5a22d7d1bfd7156dfd7a7d6cdad524b8f98596a75aa064fcbb295a36161ce288d4be4f42c5abb
diff --git a/kde-frameworks/plasma/plasma-5.101.0.ebuild b/kde-frameworks/plasma/plasma-5.101.0.ebuild
new file mode 100644
index 000000000000..a27e1ef1b167
--- /dev/null
+++ b/kde-frameworks/plasma/plasma-5.101.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_NAME="${PN}-framework"
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.5
+VIRTUALX_REQUIRED="test"
+inherit ecm frameworks.kde.org
+
+DESCRIPTION="Plasma framework"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="gles2-only man wayland X"
+
+RESTRICT="test"
+
+RDEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5[gles2-only=,X=]
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	=kde-frameworks/kactivities-${PVCUT}*:5
+	=kde-frameworks/karchive-${PVCUT}*:5
+	=kde-frameworks/kconfig-${PVCUT}*:5[qml]
+	=kde-frameworks/kconfigwidgets-${PVCUT}*:5
+	=kde-frameworks/kcoreaddons-${PVCUT}*:5
+	=kde-frameworks/kdeclarative-${PVCUT}*:5
+	=kde-frameworks/kglobalaccel-${PVCUT}*:5
+	=kde-frameworks/kguiaddons-${PVCUT}*:5
+	=kde-frameworks/ki18n-${PVCUT}*:5
+	=kde-frameworks/kiconthemes-${PVCUT}*:5
+	=kde-frameworks/kio-${PVCUT}*:5
+	=kde-frameworks/kirigami-${PVCUT}*:5
+	=kde-frameworks/knotifications-${PVCUT}*:5
+	=kde-frameworks/kpackage-${PVCUT}*:5
+	=kde-frameworks/kservice-${PVCUT}*:5
+	=kde-frameworks/kwidgetsaddons-${PVCUT}*:5
+	=kde-frameworks/kwindowsystem-${PVCUT}*:5[X?]
+	=kde-frameworks/kxmlgui-${PVCUT}*:5
+	!gles2-only? ( media-libs/libglvnd[X?] )
+	wayland? (
+		=kde-frameworks/kwayland-${PVCUT}*:5
+		media-libs/libglvnd
+	)
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+		x11-libs/libxcb
+	)
+"
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )
+"
+BDEPEND="man? ( >=kde-frameworks/kdoctools-${PVCUT}:5 )"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package !gles2-only OpenGL)
+		$(cmake_use_find_package man KF5DocTools)
+		$(cmake_use_find_package wayland EGL)
+		$(cmake_use_find_package wayland KF5Wayland)
+		-DWITHOUT_X11=$(usex !X)
+	)
+
+	ecm_src_configure
+}