media-gfx/imagemagick: Security bump to versions 6.9.7.4 and 7.0.4.4

Gentoo bug #606654

Package-Manager: Portage-2.3.3, Repoman-2.3.1

3 files changed, 180 insertions, 1 deletions

diff --git a/media-gfx/imagemagick/Manifest b/media-gfx/imagemagick/Manifest
index 31c9185a9e34..4eed814f7d21 100644
--- a/media-gfx/imagemagick/Manifest
+++ b/media-gfx/imagemagick/Manifest
@@ -2,4 +2,5 @@ DIST ImageMagick-6.9.6-2.tar.xz 8784120 SHA256 39244823fe736626fb4ea22c4b6cb4cae
 DIST ImageMagick-6.9.6-6.tar.xz 8787060 SHA256 9cd1fe001d3ecb68b7d053ede40950d411956d47afc5267acc3ca57a77070d0a SHA512 6721f9f7973d6931006314c6afa090209766432b2d14d4e37e3d11b1042797012c9fe41e469c169bbe6862cdfc4c832eac4f9a6f8c052e1c0d41e40a13c9d95e WHIRLPOOL 32b92606bf03e36e5ac09a2be9da2ddba6590093edd68aa320c6126f5406c0c82dfeaf80f31258109b2875d0c2af3ced3e27911e7df54c159c895caa6f3ff27f
 DIST ImageMagick-6.9.7-0.tar.xz 8786428 SHA256 bd657e9d348b25d35f9f8f5f5e3de64c99eed1a1a0402358030c56515570ce30 SHA512 c7f025cba1f4f07bbc6924abb53bacc929ede681c439c603486dbb7c2a213868623ab58a496ffb89d266b6934c79faadc4e61b1e5bc4ebc277cd562213941c92 WHIRLPOOL 35d054bdc6bf323840425d70ce9376fe93f31565e43ffc2d692a368315a85deaa7b362b08d13d3820de9007f97c67431e91351e34c2513ea0e5206b57a108847
 DIST ImageMagick-6.9.7-3.tar.xz 8795016 SHA256 801767344b835b810a5f88c26f062f0fa01a97264dfe9bf5e5adf59a0b5c91a1 SHA512 e0d247691d49e17a35569e2579ac63f3d7016411959d8c2e8a69042618af896a737a3ae2b3a32028e8306d78f6a7f9ec23550760f8ef0370125ab4e6c8dbd5ba WHIRLPOOL 509e32634e17b9f2604b7052291e9b1e1225957c2d5e6b625beb6ff2083b6e8758d47dff6e4af5546fd5fd72f9d7fc7fd5d806428364c448e1284536ecfea63b
-DIST ImageMagick-7.0.4-3.tar.xz 8294292 SHA256 bc09ea103a82d1c2c093889eda7e36dd0aa7aa98a06c55de4b73932838459fc4 SHA512 056e9151efe131a9ff1b9ea4edf2bcbe4eeb35b58b7ef20a1c9e041ca80d3a8cf226d75c014c4185dd0322d7b13d01c003562c0c3618eaff4d32ad2e335d5345 WHIRLPOOL 666371cbda178ef9f798da031a17f9477b730f73bdaa6203cc927253ad16f99e59bdbe4491e87a8fd30940d687a1dde97812c0ccd808e8a0895e3b23a77202fb
+DIST ImageMagick-6.9.7-4.tar.xz 8797776 SHA256 68842c55ed9c958b84aae17974961cefff4212bf7146f09fd15c09dbdc2d9629 SHA512 9ee9cf01c486575183a67e418bdbdcf4ac2b7ea2f9ff033db6a74f8271af0567da00f020dd8c18e042221d20444bed21d5d5256944ddeaf9916b62bf1844acf6 WHIRLPOOL 7c75006dafd28bb0fe02e130b4fcbae5fe54c6fbfdb29ba6b49796a14354e7aeb56b80c498eb57a4a8c7b383af025406dfeba66735ba89fd35d61125b51e7d41
+DIST ImageMagick-7.0.4-4.tar.xz 8305764 SHA256 c46975d23ff0c587219daaa3e1dbd43a54a5d7d5ec20d0bdc2c34188facdb0f9 SHA512 3dd561c3a816aebf51904bffd680d00cbfb4c36e6f37f078906c404f872c15447c2f14dabff517005a4a6ed260b090b685b7e224cb401565d4c832eb6147e6fe WHIRLPOOL 9cb95101162eb65ef0d537bab37d9d7f0876ced002acd7c4c71a16b893007ef81b10e327fd52d02c7ce8f445e6caeac213f36e6cba8f1d18762f631c6ebdbd67
diff --git a/media-gfx/imagemagick/imagemagick-7.0.4.3.ebuild b/media-gfx/imagemagick/imagemagick-6.9.7.4.ebuild
index 9d441ac62eb2..9d441ac62eb2 100644
--- a/media-gfx/imagemagick/imagemagick-7.0.4.3.ebuild
+++ b/media-gfx/imagemagick/imagemagick-6.9.7.4.ebuild
diff --git a/media-gfx/imagemagick/imagemagick-7.0.4.4.ebuild b/media-gfx/imagemagick/imagemagick-7.0.4.4.ebuild
new file mode 100644
index 000000000000..9d441ac62eb2
--- /dev/null
+++ b/media-gfx/imagemagick/imagemagick-7.0.4.4.ebuild
@@ -0,0 +1,178 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit eutils flag-o-matic libtool multilib toolchain-funcs versionator
+
+MY_P=ImageMagick-$(replace_version_separator 3 '-')
+
+DESCRIPTION="A collection of tools and libraries for many image formats"
+HOMEPAGE="http://www.imagemagick.org/"
+SRC_URI="mirror://${PN}/${MY_P}.tar.xz"
+
+LICENSE="imagemagick"
+SLOT="0/${PV}"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="autotrace bzip2 corefonts cxx djvu fftw fontconfig fpx graphviz hdri jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp pango perl png postscript q32 q64 q8 raw static-libs svg test tiff truetype webp wmf X xml zlib"
+
+RESTRICT="perl? ( userpriv )"
+
+RDEPEND="
+	dev-libs/libltdl:0
+	autotrace? ( >=media-gfx/autotrace-0.31.1 )
+	bzip2? ( app-arch/bzip2 )
+	corefonts? ( media-fonts/corefonts )
+	djvu? ( app-text/djvu )
+	fftw? ( sci-libs/fftw:3.0 )
+	fontconfig? ( media-libs/fontconfig )
+	fpx? ( >=media-libs/libfpx-1.3.0-r1 )
+	graphviz? ( media-gfx/graphviz )
+	jbig? ( >=media-libs/jbigkit-2:= )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( >=media-libs/openjpeg-2.1.0:2 )
+	lcms? ( media-libs/lcms:2= )
+	lqr? ( media-libs/liblqr )
+	opencl? ( virtual/opencl )
+	openexr? ( media-libs/openexr:0= )
+	pango? ( x11-libs/pango )
+	perl? ( >=dev-lang/perl-5.8.8:0= )
+	png? ( media-libs/libpng:0= )
+	postscript? ( app-text/ghostscript-gpl )
+	raw? ( media-gfx/ufraw )
+	svg? ( gnome-base/librsvg )
+	tiff? ( media-libs/tiff:0= )
+	truetype? (
+		media-fonts/urw-fonts
+		>=media-libs/freetype-2
+		)
+	webp? ( media-libs/libwebp:0= )
+	wmf? ( media-libs/libwmf )
+	X? (
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libXext
+		x11-libs/libXt
+		)
+	xml? ( dev-libs/libxml2:= )
+	lzma? ( app-arch/xz-utils )
+	zlib? ( sys-libs/zlib:= )"
+DEPEND="${RDEPEND}
+	!media-gfx/graphicsmagick[imagemagick]
+	virtual/pkgconfig
+	X? ( x11-proto/xextproto )"
+
+REQUIRED_USE="corefonts? ( truetype )
+	test? ( corefonts )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	default
+
+	elibtoolize # for Darwin modules
+
+	# For testsuite, see https://bugs.gentoo.org/show_bug.cgi?id=500580#c3
+	shopt -s nullglob
+	mesa_cards=$(echo -n /dev/dri/card* | sed 's/ /:/g')
+	if test -n "${mesa_cards}"; then
+		addpredict "${mesa_cards}"
+	fi
+	ati_cards=$(echo -n /dev/ati/card* | sed 's/ /:/g')
+	if test -n "${ati_cards}"; then
+		addpredict "${ati_cards}"
+	fi
+	shopt -u nullglob
+	addpredict /dev/nvidiactl
+}
+
+src_configure() {
+	local depth=16
+	use q8 && depth=8
+	use q32 && depth=32
+	use q64 && depth=64
+
+	local openmp=disable
+	use openmp && { tc-has-openmp && openmp=enable; }
+
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lnsl -lsocket
+
+	CONFIG_SHELL=$(type -P bash) \
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable hdri) \
+		$(use_enable opencl) \
+		--with-threads \
+		--with-modules \
+		--with-quantum-depth=${depth} \
+		$(use_with cxx magick-plus-plus) \
+		$(use_with perl) \
+		--with-perl-options='INSTALLDIRS=vendor' \
+		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts \
+		$(use_with bzip2 bzlib) \
+		$(use_with X x) \
+		$(use_with zlib) \
+		$(use_with autotrace) \
+		$(use_with postscript dps) \
+		$(use_with djvu) \
+		--with-dejavu-font-dir="${EPREFIX}"/usr/share/fonts/dejavu \
+		$(use_with fftw) \
+		$(use_with fpx) \
+		$(use_with fontconfig) \
+		$(use_with truetype freetype) \
+		$(use_with postscript gslib) \
+		$(use_with graphviz gvc) \
+		$(use_with jbig) \
+		$(use_with jpeg) \
+		$(use_with jpeg2k openjp2) \
+		$(use_with lcms) \
+		$(use_with lqr) \
+		$(use_with lzma) \
+		$(use_with openexr) \
+		$(use_with pango) \
+		$(use_with png) \
+		$(use_with svg rsvg) \
+		$(use_with tiff) \
+		$(use_with webp) \
+		$(use_with corefonts windows-font-dir "${EPREFIX}"/usr/share/fonts/corefonts) \
+		$(use_with wmf) \
+		$(use_with xml) \
+		--${openmp}-openmp \
+		--with-gcc-arch=no-automagic
+}
+
+src_test() {
+	LD_LIBRARY_PATH="${S}/coders/.libs:${S}/filters/.libs:${S}/Magick++/lib/.libs:${S}/magick/.libs:${S}/wand/.libs" \
+	emake check
+}
+
+src_install() {
+	# Ensure documentation installation files and paths with each release!
+	emake \
+		DESTDIR="${D}" \
+		DOCUMENTATION_PATH="${EPREFIX}"/usr/share/doc/${PF}/html \
+		install
+
+	rm -f "${ED}"/usr/share/doc/${PF}/html/{ChangeLog,LICENSE,NEWS.txt}
+	dodoc {AUTHORS,README}.txt ChangeLog
+
+	if use perl; then
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
+	fi
+
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+
+	if use opencl; then
+		cat <<-EOF > "${T}"/99${PN}
+		SANDBOX_PREDICT="/dev/nvidiactl:/dev/ati/card:/dev/dri/card"
+		EOF
+
+		insinto /etc/sandbox.d
+		doins "${T}"/99${PN} #472766
+	fi
+
+	insinto /usr/share/${PN}
+	doins config/*icm
+}