media-libs/libshumate: add 1.1.4

Signed-off-by: Mart Raudsepp <leio@gentoo.org>

2 files changed, 64 insertions, 0 deletions

diff --git a/media-libs/libshumate/Manifest b/media-libs/libshumate/Manifest
index 029843d9b5b8..adeca25d0b47 100644
--- a/media-libs/libshumate/Manifest
+++ b/media-libs/libshumate/Manifest
@@ -1 +1,2 @@
 DIST libshumate-1.1.3.tar.xz 299644 BLAKE2B f07a583e1fd142a0601c725840e84397ed04962f828cbc15217dcdc0d767015664a06252879416e9422cb32154406dae2742ffb511404c5923ce9acab7efae0c SHA512 163cce5c9aca2f3c52da3ecb3b4a651798e314d38a145ed4c69b0510303c72a0934c24084036ca2dfaab8b008753a37f7116b0bd2907cddc78a2aceee4f847d2
+DIST libshumate-1.1.4.tar.xz 299700 BLAKE2B 1f60b0807d99c8ea675be2ca85ada1929c51aa1a5f27bb5565ddba062626c4bde447f95ad4b7e02b6d3f57af1365501e64b5bca18dc566b3bf0ae1f47d5c638f SHA512 f2bb90255a43fbdf9b17bd69260c9054378959900adbc26db9b7417f98595f1d5c9221db4f31b78a546f7bd30d95175f4210fc7db11db6704d7de4c9ad000619
diff --git a/media-libs/libshumate/libshumate-1.1.4.ebuild b/media-libs/libshumate/libshumate-1.1.4.ebuild
new file mode 100644
index 000000000000..94e5f6d11dba
--- /dev/null
+++ b/media-libs/libshumate/libshumate-1.1.4.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org meson vala virtualx
+
+DESCRIPTION="Shumate is a GTK toolkit providing widgets for embedded maps"
+HOMEPAGE="https://wiki.gnome.org/Projects/libshumate https://gitlab.gnome.org/GNOME/libshumate"
+
+SLOT="1.0/1"
+LICENSE="LGPL-2.1+"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~sparc ~x86"
+REQUIRED_USE="gtk-doc? ( introspection )"
+
+IUSE="gtk-doc +introspection sysprof vala" # vector-renderer is still experimental, maybe put in at a later release
+
+RDEPEND="
+	>=dev-libs/glib-2.68.0:2
+	>=x11-libs/cairo-1.4
+	>=dev-db/sqlite-1.12:3
+	>=gui-libs/gtk-4:4
+	>=net-libs/libsoup-3.0:3.0
+	introspection? ( >=dev-libs/gobject-introspection-0.6.3:= )
+"
+# vector-renderer? (
+#	>=dev-libs/json-glib-1.6.0[introspection?]
+#	dev-libs/protobuf-c
+# )
+
+DEPEND="${RDEPEND}
+	sysprof? ( dev-util/sysprof-capture:4 )
+"
+BDEPEND="
+	gtk-doc? ( >=dev-util/gi-docgen-2021.1 )
+	vala? ( $(vala_depend) )
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use introspection gir)
+		$(meson_use vala vapi)
+		$(meson_use gtk-doc gtk_doc)
+		-Ddemos=false # only built, not installed
+		# $(meson_use vector-renderer vector_renderer)
+		-Dvector_renderer=false
+		-Dlibsoup3=true
+		$(meson_feature sysprof)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx dbus-run-session meson test -C "${BUILD_DIR}" || die 'tests failed'
+}
+
+src_install() {
+	meson_src_install
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html || die
+		mv "${ED}"/usr/share/doc/libshumate-1.0 "${ED}"/usr/share/gtk-doc/html/libshumate-1.0 || die
+	fi
+}