media-sound/gnome-music: bump to 3.30.2

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

2 files changed, 78 insertions, 0 deletions

diff --git a/media-sound/gnome-music/Manifest b/media-sound/gnome-music/Manifest
index ae1fec33ad2c..59b2b6ebff75 100644
--- a/media-sound/gnome-music/Manifest
+++ b/media-sound/gnome-music/Manifest
@@ -1,3 +1,4 @@
 DIST gnome-music-3.24.2.tar.xz 1557848 BLAKE2B 329d60da4c2c601524e01bddf086ea699bc10ea311d440ae24af0a83829d7ad4c351963e1b08bd30a8538c9b9987d9f2a41f95690ae31e75c06aac0cc9db2dcf SHA512 a922c80f922b9231e9bbe0cbd1fd33c059c719350c250dbb24316224e3306de7576303119fc9ec303f569559c36d6b076b5ec1076b4f9221a8fb133dcd9f040e
 DIST gnome-music-3.26.2.tar.xz 1563244 BLAKE2B 5a5d27b34470a49a752cb67a1040e227595fd15c6ca4f7656818636d614dfef8ec082dc014ea05c271f512f7c362dc2f81a38359ef04e0663467f62ff3ac2423 SHA512 e8efe31003a54b6cfea151c5402c4d06e48928be7b79332f7f9fb8a567ff7d0d42a43e943398ad6cb7e391d0162322c7fde74922a4b16e52ec24691cc1bfc5b0
 DIST gnome-music-3.28.2.1.tar.xz 2990404 BLAKE2B e91f0bb569eb7d61b0b3136a2f5c22e35dab10f9a3a0412e387ee9f23b8be811eafdde0394ec66df7915ae9c6eb899d479d1462bc9e70d678842ebe3f8417fb5 SHA512 d50dc84ccee7c65391bbc3a5fa48e75be82f633bbfeb4082f7d76ea21fb53c03af00c79088f12ce43a677737265485b20a3736415f1592acfa185140d4142c59
+DIST gnome-music-3.30.2.tar.xz 3027580 BLAKE2B 9cd5a10fecbf7fb962455bec7ee5392a305f3bab9ebb3e2f0d24066ffd6975377c57a722e850ee340e2990f61b06456f1fe963b80d57030416af7ea3b7f92b32 SHA512 b9fa33ccb76d747e22e1144b2c77dc88432386fdfd4f52720cb1ae3230c06fb899fec654dc1e126103e393eb0358a4385099743abe26505b9b7dcffe2d04a8c8
diff --git a/media-sound/gnome-music/gnome-music-3.30.2.ebuild b/media-sound/gnome-music/gnome-music-3.30.2.ebuild
new file mode 100644
index 000000000000..8ce1cedf008a
--- /dev/null
+++ b/media-sound/gnome-music/gnome-music-3.30.2.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+inherit gnome.org gnome2-utils meson python-single-r1 xdg
+
+DESCRIPTION="Music management for Gnome"
+HOMEPAGE="https://wiki.gnome.org/Apps/Music"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+KEYWORDS="~amd64 ~x86"
+
+# At 3.30.2 libdazzle only used from .ui file, thus introspection not needed
+COMMON_DEPEND="${PYTHON_DEPS}
+	net-libs/gnome-online-accounts[introspection]
+	>=dev-libs/gobject-introspection-1.54:=
+	>=x11-libs/gtk+-3.19.3:3[introspection]
+	>=dev-libs/libdazzle-3.28.0
+	>=media-libs/libmediaart-1.9.1:2.0[introspection]
+	net-libs/libsoup:2.4[introspection]
+	>=app-misc/tracker-1.99.1:=[introspection(+)]
+	>=dev-python/pygobject-3.29.1:3[cairo,${PYTHON_USEDEP}]
+	>=dev-python/pycairo-1.14.0[${PYTHON_USEDEP}]
+	>=media-libs/grilo-0.3.4:0.3[introspection]
+	>=media-plugins/grilo-plugins-0.3.8:0.3
+"
+# xdg-user-dirs-update needs to be there to create needed dirs
+# https://bugzilla.gnome.org/show_bug.cgi?id=731613
+RDEPEND="${COMMON_DEPEND}
+	|| (
+		>=app-misc/tracker-miners-1.99.1[gstreamer]
+		>=app-misc/tracker-miners-1.99.1[ffmpeg]
+	)
+	x11-libs/libnotify[introspection]
+	media-libs/gstreamer:1.0[introspection]
+	media-libs/gst-plugins-base:1.0[introspection]
+	media-plugins/gst-plugins-meta:1.0
+	media-plugins/grilo-plugins:0.3[tracker]
+	x11-misc/xdg-user-dirs
+"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/libxml2:2
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	python_setup
+}
+
+src_prepare() {
+	sed -e '/sys.path.insert/d' -i "${S}"/gnome-music.in || die "python fixup sed failed"
+	xdg_src_prepare
+}
+
+src_install() {
+	meson_src_install
+	python_fix_shebang "${D}"usr/bin/gnome-music
+	python_optimize
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}