media-sound/hydrogen: bump to 1.2.2 + updated live

Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

3 files changed, 100 insertions, 1 deletions

diff --git a/media-sound/hydrogen/Manifest b/media-sound/hydrogen/Manifest
index 1c00035212f9..0f072277bdd9 100644
--- a/media-sound/hydrogen/Manifest
+++ b/media-sound/hydrogen/Manifest
@@ -1 +1,2 @@
 DIST hydrogen-1.2.1.tar.gz 12920203 BLAKE2B 3ddc92fdab9a07c26aa1d00239a23dd7aeb2014cf5e71023ef3ccfee880fb9a568cad6de94c9cdaf2037bab5dbe500cfbaaac14c02a608f002866927cb75dc61 SHA512 aa6faadaf43da1ab6f514223bf7c8b526daac8dcd17916a0fdea098d6f80a33170ca3aaa210e2aedea7546221fb2aacaabf365d1457b5a25fb81f51780405ff2
+DIST hydrogen-1.2.2.tar.gz 12948890 BLAKE2B 30d8624078a29a0514aee01d56865e5923f755de02acfddde45a26d6ffbd68cf3c8c774827fe4538b7d03faefaabb9ddcfd9a28bb404c535ad7f6734eb5b1aff SHA512 bd6b102b14d30a8e2f4ea7e405199bb34f9b7691b57c3f9f3096c9e30c25c158e3bfd40bcfdd2d449bc153b7d3d9717df401f1e7a086e33dc953247870f1dee0
diff --git a/media-sound/hydrogen/hydrogen-1.2.2.ebuild b/media-sound/hydrogen/hydrogen-1.2.2.ebuild
new file mode 100644
index 000000000000..300110e184b2
--- /dev/null
+++ b/media-sound/hydrogen/hydrogen-1.2.2.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="Advanced drum machine"
+HOMEPAGE="http://hydrogen-music.org/"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN}-music/${PN}"
+else
+	MY_PV=${PV/_/-}
+	SRC_URI="https://github.com/${PN}-music/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+	S="${WORKDIR}"/${PN}-${MY_PV}
+fi
+
+LICENSE="GPL-2 ZLIB"
+SLOT="0"
+IUSE="alsa +archive doc jack ladspa lash osc oss portaudio portmidi pulseaudio"
+
+REQUIRED_USE="lash? ( alsa )"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+CDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	dev-qt/qtxmlpatterns:5
+	media-libs/libsndfile
+	alsa? ( media-libs/alsa-lib )
+	archive? ( app-arch/libarchive )
+	!archive? ( dev-libs/libtar )
+	doc? ( dev-texlive/texlive-fontutils )
+	jack? ( virtual/jack )
+	ladspa? ( media-libs/liblrdf )
+	lash? ( media-sound/lash )
+	osc? ( media-libs/liblo )
+	portaudio? ( media-libs/portaudio )
+	portmidi? ( media-libs/portmidi )
+	pulseaudio? ( media-libs/libpulse )
+"
+DEPEND="
+	${CDEPEND}
+	dev-qt/qttest:5
+"
+RDEPEND="${CDEPEND}"
+
+DOCS=( AUTHORS ChangeLog DEVELOPERS README.md )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.2.1-gnuinstalldirs.patch"
+)
+
+src_prepare() {
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWANT_ALSA=$(usex alsa)
+		-DWANT_CPPUNIT=OFF
+		-DWANT_DEBUG=OFF
+		-DWANT_JACK=$(usex jack)
+		-DWANT_LADSPA=$(usex ladspa)
+		-DWANT_LASH=$(usex lash)
+		-DWANT_LIBARCHIVE=$(usex archive)
+		-DWANT_LRDF=$(usex ladspa)
+		-DWANT_OSC=$(usex osc)
+		-DWANT_OSS=$(usex oss)
+		-DWANT_PORTAUDIO=$(usex portaudio)
+		-DWANT_PORTMIDI=$(usex portmidi)
+		-DWANT_PULSEAUDIO=$(usex pulseaudio)
+		-DWANT_RUBBERBAND=OFF
+	)
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use doc && cmake_src_compile doc
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( "${BUILD_DIR}"/docs/html/. )
+	cmake_src_install
+}
diff --git a/media-sound/hydrogen/hydrogen-9999.ebuild b/media-sound/hydrogen/hydrogen-9999.ebuild
index 951d4fb7a1fc..300110e184b2 100644
--- a/media-sound/hydrogen/hydrogen-9999.ebuild
+++ b/media-sound/hydrogen/hydrogen-9999.ebuild
@@ -37,7 +37,7 @@ CDEPEND="
 	dev-qt/qtwidgets:5
 	dev-qt/qtxml:5
 	dev-qt/qtxmlpatterns:5
-	>=media-libs/libsndfile-1.0.18
+	media-libs/libsndfile
 	alsa? ( media-libs/alsa-lib )
 	archive? ( app-arch/libarchive )
 	!archive? ( dev-libs/libtar )