net-irc/irssi: add 1.4.1

Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 118 insertions, 37 deletions

diff --git a/net-irc/irssi/Manifest b/net-irc/irssi/Manifest
index dc5612c9c0f4..a54639bcc796 100644
--- a/net-irc/irssi/Manifest
+++ b/net-irc/irssi/Manifest
@@ -1 +1,2 @@
 DIST irssi-1.2.3.tar.xz 1145292 BLAKE2B 7b2b7cb8d1533a06ad3cd5e0b2e45bba636cf19d26c69e19fc7e9408313f80d80a26ff2bf5f21a8763d8adec722bb33f6b076a863e6a55e178a814a3e79c9db7 SHA512 826b7bfd86a54647f2d344b6c461e1118b7382fb1637cf33c395af41a9a4ca5d8a794a415f0f0737178968cf2463bb46a0e7b7fd7014c968668b16183e0644bc
+DIST irssi-1.4.1.tar.xz 1210772 BLAKE2B b02dfeae1e3ac5d52c5d22f8d2284e0314d9c39628e5389eed2a90d22904754869567750909b65315472068113f1efa8e304696564e2c2517b7a17219cf92dda SHA512 e0c53c456bd92af60e8845dba6d338bc0f880639ba19118c22324a5044101a16f7a387377f2a15aa74364f75fe9ed0d5fac0f353c3ea2158190f76ed89dfdd22
diff --git a/net-irc/irssi/irssi-1.4.1.ebuild b/net-irc/irssi/irssi-1.4.1.ebuild
new file mode 100644
index 000000000000..4e50d26f1c07
--- /dev/null
+++ b/net-irc/irssi/irssi-1.4.1.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+GENTOO_DEPEND_ON_PERL="no"
+inherit perl-module meson
+
+DESCRIPTION="A modular textUI IRC client with IPv6 support"
+HOMEPAGE="https://irssi.org/"
+if [[ ${PV} == *9999* ]] ; then
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
+	inherit meson git-r3
+else
+	# Keep for _rc compability
+	MY_P="${P/_/-}"
+
+	SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV/_/-}/${MY_P}.tar.xz"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="otr +perl selinux +proxy"
+
+RDEPEND="
+	>=dev-libs/glib-2.6.0
+	dev-libs/openssl:=
+	sys-libs/ncurses:=
+	otr? (
+		>=dev-libs/libgcrypt-1.2.0:=
+		>=net-libs/libotr-4.1.0
+	)
+	perl? ( dev-lang/perl:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	dev-lang/perl
+	|| (
+		www-client/lynx
+		www-client/elinks
+	)
+"
+RDEPEND+=" selinux? ( sec-policy/selinux-irc )"
+
+src_configure() {
+	local emesonargs=(
+		-Ddocdir="${EPREFIX}"/usr/share/doc/${PF}
+		-Dwith-perl-lib=vendor
+		-Dwith-otr=$(usex otr)
+		-Dwith-proxy=$(usex proxy)
+		-Dwith-perl=$(usex perl)
+
+		# Carried over from autotools (for now?), bug #677804
+		-Ddisable-utf8proc=yes
+		-Dwith-fuzzer=no
+		-Dinstall-glib=no
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	# We don't want perl-module's src_test
+	meson_src_test
+}
+
+src_install() {
+	meson_src_install
+
+	use perl && perl_delete_localpod
+
+	rm -f "${ED}"/usr/$(get_libdir)/irssi/modules/*.{a,la} || die
+
+	dodoc AUTHORS ChangeLog README.md TODO NEWS
+}
diff --git a/net-irc/irssi/irssi-9999.ebuild b/net-irc/irssi/irssi-9999.ebuild
index a73888fc5871..4e50d26f1c07 100644
--- a/net-irc/irssi/irssi-9999.ebuild
+++ b/net-irc/irssi/irssi-9999.ebuild
@@ -1,68 +1,72 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI="6"
+EAPI=8
 
 GENTOO_DEPEND_ON_PERL="no"
-
-inherit autotools perl-module git-r3
-
-EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
+inherit perl-module meson
 
 DESCRIPTION="A modular textUI IRC client with IPv6 support"
 HOMEPAGE="https://irssi.org/"
+if [[ ${PV} == *9999* ]] ; then
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
+	inherit meson git-r3
+else
+	# Keep for _rc compability
+	MY_P="${P/_/-}"
+
+	SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV/_/-}/${MY_P}.tar.xz"
+fi
+
 LICENSE="GPL-2"
 SLOT="0"
-IUSE="otr +perl selinux socks5 +proxy"
+IUSE="otr +perl selinux +proxy"
 
-COMMON_DEPEND="sys-libs/ncurses:0=
+RDEPEND="
 	>=dev-libs/glib-2.6.0
 	dev-libs/openssl:=
+	sys-libs/ncurses:=
 	otr? (
-		>=dev-libs/libgcrypt-1.2.0:0=
+		>=dev-libs/libgcrypt-1.2.0:=
 		>=net-libs/libotr-4.1.0
 	)
 	perl? ( dev-lang/perl:= )
-	socks5? ( >=net-proxy/dante-1.1.18 )"
-
-DEPEND="
-	${COMMON_DEPEND}
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
 	virtual/pkgconfig
 	dev-lang/perl
 	|| (
 		www-client/lynx
 		www-client/elinks
-	)"
-
-RDEPEND="
-	${COMMON_DEPEND}
-	selinux? ( sec-policy/selinux-irc )"
+	)
+"
+RDEPEND+=" selinux? ( sec-policy/selinux-irc )"
 
-src_prepare() {
-	sed -i -e /^autoreconf/d autogen.sh || die
-	NOCONFIGURE=1 ./autogen.sh || die
+src_configure() {
+	local emesonargs=(
+		-Ddocdir="${EPREFIX}"/usr/share/doc/${PF}
+		-Dwith-perl-lib=vendor
+		-Dwith-otr=$(usex otr)
+		-Dwith-proxy=$(usex proxy)
+		-Dwith-perl=$(usex perl)
+
+		# Carried over from autotools (for now?), bug #677804
+		-Ddisable-utf8proc=yes
+		-Dwith-fuzzer=no
+		-Dinstall-glib=no
+	)
 
-	default
-	eautoreconf
+	meson_src_configure
 }
 
-src_configure() {
-	# Disable automagic dependency on dev-libs/libutf8proc (bug #677804)
-	export ac_cv_lib_utf8proc_utf8proc_version=no
-
-	local myeconfargs=(
-		--with-perl-lib=vendor
-		--enable-true-color
-		$(use_with otr)
-		$(use_with proxy)
-		$(use_with perl)
-		$(use_with socks5 socks)
-	)
-	econf "${myeconfargs[@]}"
+src_test() {
+	# We don't want perl-module's src_test
+	meson_src_test
 }
 
 src_install() {
-	default
+	meson_src_install
 
 	use perl && perl_delete_localpod