net-libs/gnome-online-accounts: Bump to 3.50.4

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/38092
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

2 files changed, 78 insertions, 0 deletions

diff --git a/net-libs/gnome-online-accounts/Manifest b/net-libs/gnome-online-accounts/Manifest
index b0ccd53acc7c..7d337af181b6 100644
--- a/net-libs/gnome-online-accounts/Manifest
+++ b/net-libs/gnome-online-accounts/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-online-accounts-3.48.1.tar.xz 383124 BLAKE2B a9e18bf034454429a84be0920110f4d74fba9462fb1f7f23e74f304e963323413d99af2d84caa9ef1c6841917f5b8249ac94dc433ba04546f2ae23d6268dcd70 SHA512 8f191994b8f38bee4b922b10b94e96d6f7cb323de0e9a1f29febea848cb2002320357262ccf6f28839e32e9216faeb28a871f878e1ad9478c61650fdd3549737
 DIST gnome-online-accounts-3.50.3.tar.xz 406404 BLAKE2B ff1d52b76720ccc28619a988d6c9a584cf8a44a9919368761c64d3b39e735b740ca1eb3ce18cd11e6998ee1a68deee12b0dc838f76c733a650fdf7ee72700a09 SHA512 c8ac65e9610ced7644239d72ab7bb137eea3ac9ca266c79ca0ad75f16982ba10bea7a880259309bbd96aedd057091eb088c78a86756fc24332f0ad7b37683a46
+DIST gnome-online-accounts-3.50.4.tar.xz 407300 BLAKE2B 7e8759c2f3c44312081a4bff774335867ced068ca94709db5ecb300bcd7aa1ca56d0d986679d4e3113b9df6fd6af1ec41066fa6f1cffff888563341061bc45fb SHA512 f0f3d6186cd436cac3f6f3624062fedce7035726cf148a75c1929d9e2b3b6813eab774c12fb6d54fb86fcb2154e016abe5a861d847048cd2a38d3b67e8867857
diff --git a/net-libs/gnome-online-accounts/gnome-online-accounts-3.50.4.ebuild b/net-libs/gnome-online-accounts/gnome-online-accounts-3.50.4.ebuild
new file mode 100644
index 000000000000..4989d24db326
--- /dev/null
+++ b/net-libs/gnome-online-accounts/gnome-online-accounts-3.50.4.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org meson vala xdg
+
+DESCRIPTION="GNOME framework for accessing online accounts"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-online-accounts"
+
+LICENSE="LGPL-2+"
+SLOT="0/1"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+IUSE="debug gnome gtk-doc +introspection kerberos man ms365 +vala"
+REQUIRED_USE="vala? ( introspection )"
+
+# libsoup used in goaoauthprovider
+# goa kerberos provider is incompatible with app-crypt/heimdal, see
+# https://bugzilla.gnome.org/show_bug.cgi?id=692250
+# json-glib-0.16 needed for bug #485092
+RDEPEND="
+	>=dev-libs/glib-2.67.4:2
+	sys-apps/dbus
+	introspection? ( >=dev-libs/gobject-introspection-0.6.2:= )
+	>=gui-libs/libadwaita-1.4
+	>=gui-libs/gtk-4.10:4
+	>=dev-libs/json-glib-0.16
+	>=app-crypt/libsecret-0.5
+	>=net-libs/libsoup-3.0:3.0
+	dev-libs/libxml2:2
+	>=net-libs/rest-0.9.0:1.0
+	kerberos? (
+		>=app-crypt/gcr-4.1.0:4=[gtk]
+		app-crypt/mit-krb5
+	)
+"
+# goa-daemon can launch gnome-control-center
+PDEPEND="gnome? ( >=gnome-base/gnome-control-center-3.2[gnome-online-accounts(+)] )"
+
+DEPEND="${RDEPEND}
+	vala? ( $(vala_depend) )
+	dev-libs/libxslt
+	>=dev-util/gdbus-codegen-2.30.0
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+
+	dev-libs/gobject-introspection-common
+	gnome-base/gnome-common
+"
+BDEPEND="gtk-doc? ( dev-util/gtk-doc )"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+}
+
+src_configure() {
+	# TODO: Give users a way to set the G/FB/Windows Live secrets
+	local emesonargs=(
+		-Dgoabackend=true
+		-Dexchange=true
+		-Dfedora=false
+		-Dgoogle=true
+		-Dimap_smtp=true
+		$(meson_use kerberos)
+		-Downcloud=true
+		-Dwebdav=true
+		-Dwindows_live=true
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use ms365 ms_graph)
+		$(meson_use introspection)
+		-Dman=true
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}