net-misc/nextcloud-client: add 3.4.4

Signed-off-by: Florian Schmaus <flow@gentoo.org>

2 files changed, 97 insertions, 0 deletions

diff --git a/net-misc/nextcloud-client/Manifest b/net-misc/nextcloud-client/Manifest
index 26b0fb0ccb50..c8e1764c2cb6 100644
--- a/net-misc/nextcloud-client/Manifest
+++ b/net-misc/nextcloud-client/Manifest
@@ -1,3 +1,4 @@
 DIST nextcloud-client-3.3.6.tar.gz 14106065 BLAKE2B b4f1179787a835f7fa203dfeaa2091eb1368f15ea6252dbf2ddd2d1a46786752f3a896574283c9ebc3faeaa024272c20fa67e4ee08b8ebca319d224ad4eb19f5 SHA512 d6c16ebd8af0d97f412102cfa9f7b7d4ca502ff5d025618f3a98a33a068dce9d0b71ee71e7b3c3a02219929584559a1237d57b1a7aa27ad8234653b56530c9f0
 DIST nextcloud-client-3.4.2.tar.gz 14329069 BLAKE2B 5a23e9a7535aff3591d73d2b17abf71cb6302b9acfa41a1de051d42d9acb4cf4d76ed1dff3c73ec989a066c51d4fe9e94d6e71718f9fc0533d0c0e2bb0949060 SHA512 9788fd658c9e7c3b26eb3c41934ee75222aba0afd38e1fd71f8f04472bf4971e5cc7c12469f0b3f909f4dc1e5aa1a063ae1324f6a8b6052cdf9b3c8c1cc8c909
 DIST nextcloud-client-3.4.3.tar.gz 14338935 BLAKE2B c9d03e0d950764537aa883da88603746ccd8818c9d0659f8df009a2550ea33f2f51f12448327b7a73a9106e310860b8399a2d12cf18c2c6b7a8f5fa2b7652148 SHA512 b3a9aa019ea2f01ffe74fe1a39c37f3d61cfa4c4b9a520d4f17061960c388541abf0c6541d60d2beed4de26f7fa18fdbef42121d9150c6b916d566bd7285ba71
+DIST nextcloud-client-3.4.4.tar.gz 14352142 BLAKE2B 104af477a15adc30885bd4d6c5fa022efc89d63c9294c8a632349999ed60b95ad1a34bdc8fed8602fd60f4fbff7c9dca2c33461bf9b167401b8d933ef9b02821 SHA512 880d615147feed915595bf6e4f99c3c7588d03b910bdee934429ccdbc16c2a0e7b07be99665729d60cb68c22a140cfd21c0cc821fd1c4499bc6ea4aec515eaf4
diff --git a/net-misc/nextcloud-client/nextcloud-client-3.4.4.ebuild b/net-misc/nextcloud-client/nextcloud-client-3.4.4.ebuild
new file mode 100644
index 000000000000..df314cf64b74
--- /dev/null
+++ b/net-misc/nextcloud-client/nextcloud-client-3.4.4.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake virtualx xdg
+
+DESCRIPTION="Desktop Syncing Client for Nextcloud"
+HOMEPAGE="https://github.com/nextcloud/desktop"
+SRC_URI="https://github.com/nextcloud/desktop/archive/v${PV/_/-}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc dolphin nautilus test webengine"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND=">=dev-db/sqlite-3.34:3
+	>=dev-libs/openssl-1.1.0:0=
+	dev-libs/qtkeychain:=[qt5(+)]
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtquickcontrols2:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwebsockets:5
+	dev-qt/qtwidgets:5
+	sys-libs/zlib
+	dolphin? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+	)
+	nautilus? ( dev-python/nautilus-python )
+	webengine? ( dev-qt/qtwebengine:5[widgets] )"
+
+DEPEND="${COMMON_DEPEND}
+	dev-qt/linguist-tools:5
+	dev-qt/qtconcurrent:5
+	dev-qt/qtxml:5
+	gnome-base/librsvg
+	doc? (
+		dev-python/sphinx
+		dev-tex/latexmk
+		dev-texlive/texlive-latexextra
+		virtual/latex-base
+	)
+	dolphin? ( kde-frameworks/extra-cmake-modules )
+	test? (
+		dev-util/cmocka
+		dev-qt/qttest:5
+	)"
+
+RDEPEND="${COMMON_DEPEND}"
+
+S="${WORKDIR}/desktop-${PV/_/-}"
+
+src_prepare() {
+	# We do not package libcloudproviders
+	sed -e "s/pkg_check_modules.*cloudproviders/#&/" -i CMakeLists.txt || die
+
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DBUILD_UPDATER=OFF
+		$(cmake_use_find_package doc Sphinx)
+		$(cmake_use_find_package doc PdfLatex)
+		$(cmake_use_find_package webengine Qt5WebEngine)
+		$(cmake_use_find_package webengine Qt5WebEngineWidgets)
+		-DBUILD_SHELL_INTEGRATION_DOLPHIN=$(usex dolphin)
+		-DBUILD_SHELL_INTEGRATION_NAUTILUS=$(usex nautilus)
+		-DBUILD_TESTING=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	virtx cmake_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	if ! use doc ; then
+		elog "Documentation and man pages not installed"
+		elog "Enable doc USE-flag to generate them"
+	fi
+}