net-misc/youtube-dl: Version 2019.11.22

Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

2 files changed, 70 insertions, 0 deletions

diff --git a/net-misc/youtube-dl/Manifest b/net-misc/youtube-dl/Manifest
index e04e784072e1..4f9c961572fc 100644
--- a/net-misc/youtube-dl/Manifest
+++ b/net-misc/youtube-dl/Manifest
@@ -1 +1,2 @@
 DIST youtube-dl-2019.11.05.tar.gz 3159084 BLAKE2B 9db643c3f3fafa0ee0b35b24afa411a169fe91f4dc2dd756ce1d3ce4b0db32cb483bca9cafdde6395232f38d5bafe90cca065fe7c1359f35d26e75dfecdb8bc3 SHA512 ec6d42e61d01e7f4087e980953c47facbbc9c5722d40f6c066789b940e084042fdc9a00266c13822a671137adf7f528fd7eb31a7849337e2e7418a722d9f865f
+DIST youtube-dl-2019.11.22.tar.gz 3154889 BLAKE2B 30eb225ce49973c918924aa96008fa0aeb3f4b148250e763446a438c46fe435927e5f7ab8866811ee537a6365e309229c5454f7b59659f8899320b07127109be SHA512 bd43d851044ab08ffd878a064aa98d2b1646fef14c4ea17f68400602dc2132209ff99213429bf8fcc2a6423758fc4add0ecff2d3c1589355a9d9627c36b78cae
diff --git a/net-misc/youtube-dl/youtube-dl-2019.11.22.ebuild b/net-misc/youtube-dl/youtube-dl-2019.11.22.ebuild
new file mode 100644
index 000000000000..89ac8f636eea
--- /dev/null
+++ b/net-misc/youtube-dl/youtube-dl-2019.11.22.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+PYTHON_COMPAT=(python{2_7,3_5,3_6,3_7})
+inherit bash-completion-r1 distutils-r1 readme.gentoo-r1
+
+DESCRIPTION="Download videos from YouTube.com (and more sites...)"
+HOMEPAGE="https://github.com/ytdl-org/youtube-dl/"
+SRC_URI="https://youtube-dl.org/downloads/${PV}/${P}.tar.gz"
+LICENSE="public-domain"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
+RESTRICT="test"
+SLOT="0"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+	|| (
+		dev-python/pycryptodome[${PYTHON_USEDEP}]
+		dev-python/pycrypto[${PYTHON_USEDEP}]
+	)
+"
+S="${WORKDIR}/${PN}"
+
+src_compile() {
+	distutils-r1_src_compile
+}
+
+python_install_all() {
+	dodoc README.txt
+	doman ${PN}.1
+
+	newbashcomp ${PN}.bash-completion ${PN}
+
+	insinto /usr/share/zsh/site-functions
+	newins ${PN}.zsh _${PN}
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins ${PN}.fish
+
+	distutils-r1_python_install_all
+
+	rm -r "${ED}"/usr/etc || die
+	rm -r "${ED}"/usr/share/doc/youtube_dl || die
+}
+
+pkg_postinst() {
+	elog "${PN}(1) / https://bugs.gentoo.org/355661 /"
+	elog "https://github.com/rg3/${PN}/blob/master/README.md#faq :"
+	elog
+	elog "${PN} works fine on its own on most sites. However, if you want"
+	elog "to convert video/audio, you'll need avconf (media-video/libav) or"
+	elog "ffmpeg (media-video/ffmpeg). On some sites - most notably YouTube -"
+	elog "videos can be retrieved in a higher quality format without sound."
+	elog "${PN} will detect whether avconv/ffmpeg is present and"
+	elog "automatically pick the best option."
+	elog
+	elog "Videos or video formats streamed via RTMP protocol can only be"
+	elog "downloaded when rtmpdump (media-video/rtmpdump) is installed."
+	elog
+	elog "Downloading MMS and RTSP videos requires either mplayer"
+	elog "(media-video/mplayer) or mpv (media-video/mpv) to be installed."
+	elog
+	elog "If you want ${PN} to embed thumbnails from the metadata into the"
+	elog "resulting MP4 files, consider installing media-video/atomicparsley"
+}