net-misc/remmina: bump to 1.4.16

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Ben Kohler <bkohler@gentoo.org>

2 files changed, 101 insertions, 0 deletions

diff --git a/net-misc/remmina/Manifest b/net-misc/remmina/Manifest
index 80bd8b6c1651..70697b0d243b 100644
--- a/net-misc/remmina/Manifest
+++ b/net-misc/remmina/Manifest
@@ -2,3 +2,4 @@ DIST Remmina-v1.4.12.tar.gz 2338965 BLAKE2B 86ec07a2c5ff0957cc3d855a4cc86c9675aa
 DIST Remmina-v1.4.13.tar.gz 2519879 BLAKE2B ff2410ffbdea4509866b41e47eaa8caafb7f45091047eff9a830590b7a04c25cbbdec5788ccf9f35afdee613722e74e7595b73b4c3c8eea2fa3ffb4e09411d99 SHA512 cf82dc90f021635bcde906a73a2ad59087fe7cbe1bdd69a828ffc1e04ea0cc1bfa23386b70c36df85ae41dfa17f2d4379bedff29c03d9838c6ac18347e06b6dc
 DIST Remmina-v1.4.14.tar.gz 2613799 BLAKE2B 07f6c78bb825395001054cb6274e3a1f45a4b2f678ee2ef629f112550742350a7e3c779a9fcd554a6654ae689cf373d7f6ed543768bdc403b9d3ef96a2ca0a2e SHA512 4114edafd2847c081f0a12cf7c7b4c2f34af554312be755a9897e161002c8dce3708041f6a3fcb340f577a2c3ccc3582909b7d0d4ecbf186f54394e4c6a98c35
 DIST Remmina-v1.4.15.tar.gz 2615051 BLAKE2B 29ad1a583bac552e0008aa9a92dbedffdb48d5e288e1bcc6daf3363eb6a753d8ae2200d14ba12cd36a54df1dd0eaec5124dfd47e636654c63101b3086bc5d420 SHA512 247e455093e18933e84d835f5d74a86f963629b1305a953f8e9a5d6262da8870690607e04c6143fee1d1f75f4735b5a500654c713df70cb61053c7912c799c3e
+DIST Remmina-v1.4.16.tar.gz 2615347 BLAKE2B 5cff71d94bf66dd0116be739646c33a601a83deb8fef1cfcddf9c197eb34458ea97f6e45e96e7e0bab7fbfb6d95c6150e5c72c6d5aae5f23bfedc8f080e00ade SHA512 a9b42ba95ab9c5f985c5c359d0fb138d73ca5f0f9199cb9e84e522d1e11c50f9fe2b8c943d64242e367f4185fd9eb0c764321ba9d4ab9a09c5c5c1dc37c0ba78
diff --git a/net-misc/remmina/remmina-1.4.16.ebuild b/net-misc/remmina/remmina-1.4.16.ebuild
new file mode 100644
index 000000000000..e7bceef93c0f
--- /dev/null
+++ b/net-misc/remmina/remmina-1.4.16.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake optfeature xdg
+
+MY_P="${PN^}-v${PV}"
+
+DESCRIPTION="A GTK+ RDP, SPICE, VNC, XDMCP and SSH client"
+HOMEPAGE="https://remmina.org/"
+SRC_URI="https://gitlab.com/Remmina/Remmina/-/archive/v${PV}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="appindicator crypt cups examples gnome-keyring gvnc kwallet nls spice ssh rdp telemetry telepathy vnc webkit zeroconf"
+
+DEPEND="
+	dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/libpcre2
+	dev-libs/libsodium:=
+	dev-libs/openssl:0=
+	dev-libs/wayland
+	net-libs/libsoup
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libxkbfile
+	appindicator? ( dev-libs/libappindicator:3 )
+	crypt? ( dev-libs/libgcrypt:0= )
+	rdp? ( >=net-misc/freerdp-2.0.0_rc4_p1129[X]
+		<net-misc/freerdp-3[X]
+		cups? ( net-print/cups:= ) )
+	gnome-keyring? ( app-crypt/libsecret )
+	gvnc? ( net-libs/gtk-vnc )
+	kwallet? ( kde-frameworks/kwallet )
+	spice? ( net-misc/spice-gtk[gtk3] )
+	ssh? ( net-libs/libssh:0=[sftp]
+		x11-libs/vte:2.91 )
+	telepathy? ( net-libs/telepathy-glib )
+	vnc? ( net-libs/libvncserver[jpeg] )
+	webkit? ( net-libs/webkit-gtk:4 )
+	zeroconf? ( >=net-dns/avahi-0.8-r2[dbus,gtk] )
+"
+BDEPEND="
+	dev-util/intltool
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+
+RDEPEND="
+	${DEPEND}
+	virtual/freedesktop-icon-theme
+"
+
+DOCS=( AUTHORS CHANGELOG.md README.md THANKS.md )
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	xdg_environment_reset
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_APPINDICATOR=$(usex appindicator)
+		-DWITH_GCRYPT=$(usex crypt)
+		-DWITH_EXAMPLES=$(usex examples)
+		-DWITH_LIBSECRET=$(usex gnome-keyring)
+		-DWITH_KF5WALLET=$(usex kwallet)
+		-DWITH_GETTEXT=$(usex nls)
+		-DWITH_TRANSLATIONS=$(usex nls)
+		-DWITH_FREERDP=$(usex rdp)
+		-DWITH_FREERDP3=OFF
+		-DWITH_CUPS=$(usex cups)
+		-DWITH_SPICE=$(usex spice)
+		-DWITH_LIBSSH=$(usex ssh)
+		-DWITH_VTE=$(usex ssh)
+		-DWITH_TELEPATHY=$(usex telepathy)
+		-DWITH_LIBVNCSERVER=$(usex vnc)
+		-DWITH_WWW=$(usex webkit)
+		-DWITH_AVAHI=$(usex zeroconf)
+		-DWITH_NEWS=$(usex telemetry)
+		-DWITH_ICON_CACHE=OFF
+		-DWITH_UPDATE_DESKTOP_DB=OFF
+		# when this feature is stable, add python eclass usage to optionally enable
+		-DWITH_PYTHON=OFF
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "encrypted VNC connections" net-libs/libvncserver[gcrypt]
+	optfeature "XDMCP support" x11-base/xorg-server[xephyr]
+}