net-vpn/ocserv: add 1.3.0

Signed-off-by: Mike Gilbert <floppym@gentoo.org>

3 files changed, 109 insertions, 2 deletions

diff --git a/net-vpn/ocserv/Manifest b/net-vpn/ocserv/Manifest
index 78a9512b8446..e2f907e3419d 100644
--- a/net-vpn/ocserv/Manifest
+++ b/net-vpn/ocserv/Manifest
@@ -2,3 +2,5 @@ DIST ocserv-1.1.6.tar.xz 839744 BLAKE2B 3b3591588d9a5be4e723df739a5d8b4c33d78d53
 DIST ocserv-1.1.6.tar.xz.sig 442 BLAKE2B d24c46783f273bd329267cb3ba4effe0280655867e619bf0a3e4191386fa8851541fcd8768b0b1068e594caaf510ceeccfc30641169679ec394706fdf1ebe319 SHA512 2a87768ad63d40053732fa011bbeb3532c9673296b9be299bf8f7d8dd3dd35571eee96c0b4fa9bf5a30633b4c844337ab3d562d6ea2b6ad8efca084eb5e6f502
 DIST ocserv-1.1.7.tar.xz 844140 BLAKE2B 0b89937ce74fcf83d6423458462b3a419f9604407c80e2fc4a732b3e481dfd98cc76f062e112bf93ee392b3f4cdf5fdd271997c878bbe4165f11fa282852ff90 SHA512 5b6182b98c0406a27dae7121ec0d8771b158e0d8ce2056bd35451c8ed087a8b7f7d40035f9db5c19aa9a9a3b2c6b07be8f0bad4b6b96569584815a5358202ba4
 DIST ocserv-1.1.7.tar.xz.sig 442 BLAKE2B f5c40ef16f3bd4fb3dadff0459a6ecf8fadae01733a3d718ec00f35980b08860f7947c04a99386209a391185590edaedc349e9cb6684159178cd91caaf2f11fd SHA512 96d2562fdf918f2b6ea829d747330a3be2e015ab25897e01bd0d387cb69ef3592aacabbeec9612e95eca1fbce6178a176dbf76d553b7626c09d453d216ddd63d
+DIST ocserv-1.3.0.tar.xz 770596 BLAKE2B b45c528ca0d12602ae05cebf469a4be2efa846a49540375b258901620a9b95135297fdbb6553cec2cf63b506bcfc9355df8b519bcd6d52684b3b7432dbe66380 SHA512 24c3129b389fa767ad14f158580d8abd6830e697162b8fcfe3df6a4d21d543460c1955c3e0c63fecb8b4b01bd2492254d3eea8d5ba60d864cea314325badda7e
+DIST ocserv-1.3.0.tar.xz.sig 442 BLAKE2B f73b98c71a0c3fe18bf540e84871a51d28b8993ba9ae719f89fa345412a609d062b2041cd9b0e4b6aae8eecf8a117c68d408153b0ea15c7b1277f3d2ebcec567 SHA512 dd6a2e6f28a512bda19e758b32149cfe7951151edab8c34ac371dbcd17eed4a8b10fdfee306629c1d42c2a3e22bcfe523ee2aafb84d59181d5be719c399cfb7d
diff --git a/net-vpn/ocserv/ocserv-1.3.0.ebuild b/net-vpn/ocserv/ocserv-1.3.0.ebuild
new file mode 100644
index 000000000000..52512265f732
--- /dev/null
+++ b/net-vpn/ocserv/ocserv-1.3.0.ebuild
@@ -0,0 +1,105 @@
+# Copyright 2019-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit systemd
+
+if [[ ${PV} == 9999 ]]; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://gitlab.com/openconnect/ocserv.git"
+else
+	inherit verify-sig
+	VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/ocserv.asc"
+	BDEPEND="verify-sig? ( sec-keys/openpgp-keys-ocserv )"
+	SRC_URI="https://www.infradead.org/ocserv/download/${P}.tar.xz
+		verify-sig? ( https://www.infradead.org/ocserv/download/${P}.tar.xz.sig )"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+fi
+
+DESCRIPTION="Openconnect SSL VPN server"
+HOMEPAGE="https://ocserv.gitlab.io/www/index.html"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="geoip kerberos +lz4 otp pam radius +seccomp systemd tcpd test"
+RESTRICT="!test? ( test )"
+
+BDEPEND+="
+	virtual/pkgconfig
+	test? (
+		net-libs/gnutls[tools(+)]
+		net-libs/socket_wrapper
+		net-misc/ipcalc
+		net-vpn/openconnect
+		sys-libs/nss_wrapper
+		sys-libs/uid_wrapper
+		pam? ( sys-libs/pam_wrapper )
+	)
+"
+DEPEND="
+	dev-libs/libnl:3=
+	dev-libs/libev:0=
+	>=dev-libs/nettle-2.7:0=
+	dev-libs/pcl:0=
+	dev-libs/protobuf-c:0=
+	>=net-libs/gnutls-3.3.0:0=
+	sys-libs/readline:0=
+	sys-libs/talloc:0=
+	virtual/libcrypt:=
+	geoip? ( dev-libs/geoip:0= )
+	kerberos? ( virtual/krb5 )
+	lz4? ( app-arch/lz4:0= )
+	otp? ( sys-auth/oath-toolkit:0= )
+	pam? ( sys-libs/pam:0= )
+	radius? ( net-dialup/freeradius-client:0= )
+	seccomp? ( sys-libs/libseccomp:0= )
+	systemd? ( sys-apps/systemd:0= )
+	tcpd? ( sys-apps/tcp-wrappers:0= )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+	if [[ ${PV} == 9999 ]]; then
+		eautoreconf
+	fi
+}
+
+src_configure() {
+	local myconf=(
+		--without-root-tests
+
+		$(use_enable seccomp)
+		$(use_enable systemd)
+
+		$(use_with geoip)
+		$(use_with kerberos gssapi)
+		--without-llhttp
+		$(use_with lz4)
+		$(use_with otp liboath)
+		$(use_with radius)
+		$(use_with tcpd libwrap)
+	)
+	econf "${myconf[@]}"
+}
+
+src_test() {
+	addwrite /proc
+	default
+}
+
+src_install() {
+	default
+
+	dodoc doc/sample.{config,passwd}
+	use otp && dodoc doc/sample.otp
+
+	doinitd "${FILESDIR}"/ocserv
+
+	if use systemd; then
+		systemd_dounit doc/systemd/socket-activated/ocserv.{service,socket}
+	else
+		systemd_dounit doc/systemd/standalone/ocserv.service
+	fi
+}
diff --git a/net-vpn/ocserv/ocserv-9999.ebuild b/net-vpn/ocserv/ocserv-9999.ebuild
index be01b5b8a2b0..52512265f732 100644
--- a/net-vpn/ocserv/ocserv-9999.ebuild
+++ b/net-vpn/ocserv/ocserv-9999.ebuild
@@ -30,6 +30,7 @@ BDEPEND+="
 	test? (
 		net-libs/gnutls[tools(+)]
 		net-libs/socket_wrapper
+		net-misc/ipcalc
 		net-vpn/openconnect
 		sys-libs/nss_wrapper
 		sys-libs/uid_wrapper
@@ -43,7 +44,6 @@ DEPEND="
 	dev-libs/pcl:0=
 	dev-libs/protobuf-c:0=
 	>=net-libs/gnutls-3.3.0:0=
-	net-libs/http-parser:0=
 	sys-libs/readline:0=
 	sys-libs/talloc:0=
 	virtual/libcrypt:=
@@ -69,13 +69,13 @@ src_prepare() {
 src_configure() {
 	local myconf=(
 		--without-root-tests
-		--without-nuttcp-tests
 
 		$(use_enable seccomp)
 		$(use_enable systemd)
 
 		$(use_with geoip)
 		$(use_with kerberos gssapi)
+		--without-llhttp
 		$(use_with lz4)
 		$(use_with otp liboath)
 		$(use_with radius)