net-wireless/wavemon: Version bump to 0.9.4

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Alarig Le Lay <alarig@swordarmor.fr>
Closes: https://github.com/gentoo/gentoo/pull/22351
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 53 insertions, 0 deletions

diff --git a/net-wireless/wavemon/wavemon-0.9.4.ebuild b/net-wireless/wavemon/wavemon-0.9.4.ebuild
new file mode 100644
index 000000000000..34f9f37a2b5b
--- /dev/null
+++ b/net-wireless/wavemon/wavemon-0.9.4.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools linux-info
+
+DESCRIPTION="Ncurses based monitor for IEEE 802.11 wireless LAN cards"
+HOMEPAGE="https://github.com/uoaerg/wavemon/"
+SRC_URI="https://github.com/uoaerg/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~sparc ~x86"
+
+IUSE="caps"
+RDEPEND="
+	dev-libs/libnl:3[utils]
+	sys-libs/ncurses:0=
+	caps? ( sys-libs/libcap )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+DOCS=( README.md )
+
+PATCHES=(
+	"${FILESDIR}/${P}-build.patch"
+)
+
+pkg_pretend() {
+	local CONFIG_CHECK="~CFG80211"
+
+	check_extra_config
+}
+
+src_prepare() {
+	# Do not install docs to /usr/share
+	sed -i -e '/^install:/s/install-docs//' Makefile.in || die \
+		'sed on Makefile.in failed'
+
+	# automagic on libcap, discovered in bug #448406
+	use caps || export ac_cv_lib_cap_cap_get_flag=false
+
+	default_src_prepare
+	eautoreconf
+}
+
+src_install() {
+	default_src_install
+	# Install man files manually(bug #397807)
+	doman wavemon.1
+	doman wavemonrc.5
+}