sci-libs/bliss: fix gmp automagic, add prefix, minor cosmetic fixes

Package-Manager: Portage-2.3.6, Repoman-2.3.3

1 files changed, 48 insertions, 0 deletions

diff --git a/sci-libs/bliss/bliss-0.73-r1.ebuild b/sci-libs/bliss/bliss-0.73-r1.ebuild
new file mode 100644
index 000000000000..de9e1f385274
--- /dev/null
+++ b/sci-libs/bliss/bliss-0.73-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools
+
+SRC_URI="http://www.tcs.hut.fi/Software/${PN}/${P}.zip"
+DESCRIPTION="Compute Automorphism Groups and Canonical Labelings of Graphs"
+HOMEPAGE="http://www.tcs.hut.fi/Software/bliss/"
+
+LICENSE="LGPL-3"
+SLOT="0/1"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc gmp static-libs"
+
+RDEPEND="gmp? ( dev-libs/gmp:0= )"
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	doc? ( app-doc/doxygen )"
+
+#patches from http://pkgs.fedoraproject.org/cgit/rpms/bliss.git/tree/
+PATCHES=(
+	"${FILESDIR}"/${P}-error.patch
+	"${FILESDIR}"/${P}-rehn.patch
+	"${FILESDIR}"/${P}-autotools.patch
+)
+
+src_prepare() {
+	default
+	cp "${FILESDIR}/${P}.1.in" "${PN}.1.in" || die
+	rm Makefile || die
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_with gmp) $(use_enable static-libs static)
+}
+
+src_compile() {
+	emake all $(usex doc html "")
+}
+
+src_install() {
+	default
+	use static-libs || find "${ED}" -name '*.la' -delete
+	use doc && dodoc -r html
+}