sci-libs/nemesis: version bump

Package-Manager: portage-2.2.28

1 files changed, 48 insertions, 0 deletions

diff --git a/sci-libs/nemesis/nemesis-6.09.ebuild b/sci-libs/nemesis/nemesis-6.09.ebuild
new file mode 100644
index 000000000000..62e9e549161e
--- /dev/null
+++ b/sci-libs/nemesis/nemesis-6.09.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit cmake-utils multilib
+
+MY_PN="exodus"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Enhancement to the EXODUSII finite element database model"
+HOMEPAGE="http://sourceforge.net/projects/exodusii/"
+SRC_URI="mirror://sourceforge/project/${MY_PN}ii/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="static-libs test"
+
+DEPEND="
+	sci-libs/exodusii
+	sci-libs/netcdf"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}"/${MY_P}/${PN}
+
+PATCHES=( "${FILESDIR}"/${P}-multilib.patch )
+
+src_prepare() {
+	find ../exodus -delete || die
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	mycmakeargs=(
+		-DLIB_INSTALL_DIR=$(get_libdir)
+		-DNETCDF_DIR="${EPREFIX}/usr/"
+		-DEXODUS_DIR="${EPREFIX}/usr/"
+		$(cmake-utils_use !static-libs BUILD_SHARED_LIBS)
+		$(cmake-utils_use test BUILD_TESTING)
+	)
+	cmake-utils_src_configure
+}
+
+src_test() {
+	"${BUILD_DIR}"/ne_test || die
+}