sci-libs/volk: add 2.5.1

Signed-off-by: Rick Farina <zerochaos@gentoo.org>
Remove stray pyc/pyo files
Closes: https://bugs.gentoo.org/862990

1 files changed, 48 insertions, 0 deletions

diff --git a/sci-libs/volk/volk-2.5.1.ebuild b/sci-libs/volk/volk-2.5.1.ebuild
new file mode 100644
index 000000000000..dbfc78069397
--- /dev/null
+++ b/sci-libs/volk/volk-2.5.1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+#https://github.com/gnuradio/volk/issues/383
+CMAKE_BUILD_TYPE="None"
+inherit cmake python-single-r1
+
+DESCRIPTION="vector optimized library of kernels"
+HOMEPAGE="http://libvolk.org"
+SRC_URI="https://github.com/gnuradio/volk/releases/download/v${PV}/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~arm ~riscv ~x86"
+IUSE="orc test"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RDEPEND="${PYTHON_DEPS}
+	!<net-wireless/gnuradio-3.8
+	dev-libs/boost:=
+	orc? ( dev-lang/orc )"
+DEPEND="${RDEPEND}
+	$(python_gen_cond_dep 'dev-python/mako[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]')"
+
+RESTRICT="test"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_ORC=$(usex orc)
+		-DPYTHON_EXECUTABLE="${PYTHON}"
+		-DENABLE_TESTING="$(usex test)"
+		-DENABLE_PROFILING=OFF
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	# Remove stray python files generated by the build system
+	find "${ED}" -name '*.pyc' -exec rm -f {} \; || die
+	find "${ED}" -name '*.pyo' -exec rm -f {} \; || die
+	python_optimize
+}