sys-apps/the_silver_searcher: version bump to 1.0.1

1 files changed, 48 insertions, 0 deletions

diff --git a/sys-apps/the_silver_searcher/the_silver_searcher-1.0.1.ebuild b/sys-apps/the_silver_searcher/the_silver_searcher-1.0.1.ebuild
new file mode 100644
index 000000000000..a5255e129cbd
--- /dev/null
+++ b/sys-apps/the_silver_searcher/the_silver_searcher-1.0.1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit autotools bash-completion-r1
+
+DESCRIPTION="A code-searching tool similar to ack, but faster"
+HOMEPAGE="https://github.com/ggreer/the_silver_searcher"
+SRC_URI="https://github.com/ggreer/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="lzma test zlib"
+
+RDEPEND="dev-libs/libpcre
+	lzma? ( app-arch/xz-utils )
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	test? ( dev-util/cram )"
+
+DOCS="README.md"
+
+PATCHES=( "${FILESDIR}"/${P}-tests.patch )
+
+src_prepare() {
+	sed '/^dist_bashcomp/d' -i Makefile.am || die
+
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable lzma) \
+		$(use_enable zlib)
+}
+
+src_test() {
+	cram -v tests/*.t || die "tests failed"
+}
+
+src_install() {
+	default
+	newbashcomp ag.bashcomp.sh ag
+}