proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 78 insertions, 0 deletions

diff --git a/sys-cluster/hpx/hpx-0.9.10.ebuild b/sys-cluster/hpx/hpx-0.9.10.ebuild
new file mode 100644
index 000000000000..b481d7d9ba67
--- /dev/null
+++ b/sys-cluster/hpx/hpx-0.9.10.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit cmake-utils fortran-2 multilib python-single-r1 versionator
+
+SRC_URI="http://stellar.cct.lsu.edu/files/${PN}_${PV}.tar.gz"
+KEYWORDS="~amd64 ~x86"
+S="${WORKDIR}/${PN}_${PV}"
+
+DESCRIPTION="C++ runtime system for parallel and distributed applications"
+HOMEPAGE="http://stellar.cct.lsu.edu/tag/hpx/"
+
+SLOT="0"
+LICENSE="Boost-1.0"
+IUSE="doc examples jemalloc papi +perftools tbb test"
+
+RDEPEND="
+	tbb? ( dev-cpp/tbb )
+	>=dev-libs/boost-1.49
+	papi? ( dev-libs/papi )
+	perftools? ( >=dev-util/google-perftools-1.7.1 )
+	>=sys-apps/hwloc-1.8
+	>=sys-libs/libunwind-1
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	test? ( dev-lang/python )
+	doc? ( >=dev-libs/boost-1.56.0-r1[tools] )
+"
+REQUIRED_USE="test? ( ${PYTHON_REQUIRED_USE} )
+	jemalloc? ( !perftools !tbb )
+	perftools? ( !jemalloc !tbb )
+	tbb? ( !jemalloc !perftools )
+	"
+
+pkg_setup() {
+	use test && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	CMAKE_BUILD_TYPE=Release
+	local mycmakeargs=(
+		-DHPX_BUILD_EXAMPLES=OFF
+		-DHPX_MALLOC=system
+		-DLIB=$(get_libdir)
+		-Dcmake_dir=cmake
+		$(cmake-utils_use doc HPX_BUILD_DOCUMENTATION)
+		$(cmake-utils_use jemalloc HPX_JEMALLOC)
+		$(cmake-utils_use test BUILD_TESTING)
+		$(cmake-utils_use perftools HPX_GOOGLE_PERFTOOLS)
+		$(cmake-utils_use papi HPX_PAPI)
+	)
+
+	use perftools && mycmakeargs+=( -DHPX_MALLOC=tcmalloc )
+	use jemalloc && mycmakeargs+=( -DHPX_MALLOC=jemalloc )
+	use tbb && mycmakeargs+=( -DHPX_MALLOC=tbbmalloc )
+
+	cmake-utils_src_configure
+}
+
+src_test() {
+	# avoid over-suscribing
+	cmake-utils_src_make -j1 tests
+}
+
+src_install() {
+	cmake-utils_src_install
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r examples
+	fi
+}