sys-devel/smatch: add 1.72

Signed-off-by: Sam James <sam@gentoo.org>

4 files changed, 78 insertions, 7 deletions

diff --git a/sys-devel/smatch/Manifest b/sys-devel/smatch/Manifest
index 758f2f837322..a99bf33cb4d0 100644
--- a/sys-devel/smatch/Manifest
+++ b/sys-devel/smatch/Manifest
@@ -1 +1,2 @@
 DIST smatch-1.60.tar.gz 558479 BLAKE2B d5e564c32e33dc38847f9a258b4b47285f190652181db9b8850c832c0cf4d8a3302d989a7b42592e73a713927a29565565e83a9be1b0a5c9d10869fce278a0be SHA512 2920c9d4c500db36cfa60db5be70d157ed16abd729279462faef6f79e0756bd017ec91b8f857d19fdebd8a9d709b0555635700a2864cf0a84daa61cf2ca3eecd
+DIST smatch-1.72.tar.gz 1431923 BLAKE2B ec4119fce985876afc9a46a74a0a56e8e8cb271a964c16496972c59ade95aa3d2df3a839a819e31cb081ca8a3b1f6bf6934ec97d73209091cfd86c87c1433557 SHA512 6d12e9ba85f332fcc56657296596e811cf3b75d4ad37007e07feb31baa4b315732361915972a2139ae13f75b8a73f953488ceb9de41529db9e84c81fb6fde77e
diff --git a/sys-devel/smatch/smatch-1.60.ebuild b/sys-devel/smatch/smatch-1.60.ebuild
index 9423f1d108f6..4a6c5f79460c 100644
--- a/sys-devel/smatch/smatch-1.60.ebuild
+++ b/sys-devel/smatch/smatch-1.60.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -15,7 +15,7 @@ else
 	S=${WORKDIR}/${PN}
 fi
 
-DESCRIPTION="static analysis tool for C"
+DESCRIPTION="Static analysis tool for C"
 HOMEPAGE="http://smatch.sourceforge.net/"
 
 LICENSE="OSL-1.1"
diff --git a/sys-devel/smatch/smatch-1.72.ebuild b/sys-devel/smatch/smatch-1.72.ebuild
new file mode 100644
index 000000000000..cb53b5afd462
--- /dev/null
+++ b/sys-devel/smatch/smatch-1.72.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="git://repo.or.cz/${PN}.git
+		http://repo.or.cz/r/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="http://repo.or.cz/w/smatch.git/snapshot/${PV}.tar.gz -> ${P}.tar.gz
+		mirror://gentoo/${P}.tar.gz"
+	# Update on bumps
+	S="${WORKDIR}"/${P}-7f4b936
+
+	KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
+fi
+
+DESCRIPTION="Static analysis tool for C"
+HOMEPAGE="http://smatch.sourceforge.net/"
+
+LICENSE="OSL-1.1"
+SLOT="0"
+
+RDEPEND="dev-db/sqlite"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e '/^CFLAGS =/{s:=:+=:;s:-O2 -finline-functions:${CPPFLAGS}:}' \
+		-e 's:pkg-config:$(PKG_CONFIG):' \
+		Makefile || die
+}
+
+_emake() {
+	# gtk/llvm/xml is used by sparse which we don't install
+	emake \
+		PREFIX="${EPREFIX}/usr" \
+		V=1 \
+		AR="$(tc-getAR)" \
+		CC="$(tc-getCC)" \
+		LD='$(CC)' \
+		PKG_CONFIG="$(tc-getPKG_CONFIG)" \
+		HAVE_GTK2=no \
+		HAVE_LLVM=no \
+		HAVE_LIBXML=no \
+		"$@"
+}
+
+src_compile() {
+	_emake smatch
+}
+
+src_test() {
+	_emake check
+}
+
+src_install() {
+	# default install target installs a lot of sparse cruft
+	dobin smatch
+	insinto /usr/share/smatch/smatch_data
+	doins smatch_data/*
+	dodoc FAQ README
+}
diff --git a/sys-devel/smatch/smatch-9999.ebuild b/sys-devel/smatch/smatch-9999.ebuild
index 8ba49a55ed46..cb53b5afd462 100644
--- a/sys-devel/smatch/smatch-9999.ebuild
+++ b/sys-devel/smatch/smatch-9999.ebuild
@@ -1,25 +1,27 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
 
 inherit toolchain-funcs
 if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="git://repo.or.cz/${PN}.git
+		http://repo.or.cz/r/${PN}.git"
 	inherit git-r3
-	EGIT_REPO_URI="https://repo.or.cz/r/${PN}.git"
 else
 	SRC_URI="http://repo.or.cz/w/smatch.git/snapshot/${PV}.tar.gz -> ${P}.tar.gz
 		mirror://gentoo/${P}.tar.gz"
+	# Update on bumps
+	S="${WORKDIR}"/${P}-7f4b936
+
 	KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
-	S=${WORKDIR}/${PN}
 fi
 
-DESCRIPTION="static analysis tool for C"
+DESCRIPTION="Static analysis tool for C"
 HOMEPAGE="http://smatch.sourceforge.net/"
 
 LICENSE="OSL-1.1"
 SLOT="0"
-IUSE=""
 
 RDEPEND="dev-db/sqlite"
 DEPEND="${RDEPEND}"