xfce-base/xfce4-settings: Bump to 4.19.3

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 97 insertions, 0 deletions

diff --git a/xfce-base/xfce4-settings/Manifest b/xfce-base/xfce4-settings/Manifest
index 064b66565224..e1c117c0be43 100644
--- a/xfce-base/xfce4-settings/Manifest
+++ b/xfce-base/xfce4-settings/Manifest
@@ -1,2 +1,3 @@
 DIST xfce4-settings-4.18.6.tar.bz2 1560269 BLAKE2B c6336c98ad16c968c2400c9a888ad8eaed39d0f25116b2f767d70c4d3e75bd7f0fef8381fb8cd3105afb7b0786f0b17a285153534421748a91bc6845c252f53a SHA512 e9615e8409f597b53bf118908c0a8c5f893b335915dd009c5b7da9ba8403a0de74b751dec7482f3076cd880f2bd3cffc1f45a13a1e88196fb7f0c87c996794b7
 DIST xfce4-settings-4.19.2.tar.bz2 2433368 BLAKE2B 00175d94837c0abec841feed5d1ea834160afccae8718f4af11323d65d5d751d288dd2651b06ceee6ec02fa2ec222e5b94322a38fa59fd29a18e64a1eb84c88c SHA512 dc225dc3d4296db1dbfdd93685a29b453faab2c3259e2dd1f162d631b3853c4f2b582facab60814d1babe934c2eac752ef954dff2b285e9340dd5247f131555a
+DIST xfce4-settings-4.19.3.tar.bz2 2444442 BLAKE2B 2a77776299cba8029c54d2517cca72ac68c7177b75918838b19d0b7c18c72699a532e3fd43a049b43ba7eec1a4faa99002e362a501a5bfcb509434d56935e458 SHA512 1aeff3ba71addedb137d1b0e30af54fe5c4873d6b8d76675ede509c79017751202f46d421f9c4a8d4819910eef0a94c57ce043795a148ac9dc5984fefdab9aac
diff --git a/xfce-base/xfce4-settings/xfce4-settings-4.19.3.ebuild b/xfce-base/xfce4-settings/xfce4-settings-4.19.3.ebuild
new file mode 100644
index 000000000000..994f4dff0ae6
--- /dev/null
+++ b/xfce-base/xfce4-settings/xfce4-settings-4.19.3.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit python-single-r1 xdg-utils
+
+DESCRIPTION="Configuration system for the Xfce desktop environment"
+HOMEPAGE="
+	https://docs.xfce.org/xfce/xfce4-settings/start
+	https://gitlab.xfce.org/xfce/xfce4-settings/
+"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="X colord input_devices_libinput libcanberra libnotify upower wayland +xklavier"
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	|| ( X wayland )
+"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/glib-2.72.0
+	>=x11-libs/gtk+-3.24.0:3[X?,wayland?]
+	>=xfce-base/garcon-0.1.10:=
+	>=xfce-base/exo-0.11.0:=
+	>=xfce-base/libxfce4ui-4.19.5:=
+	>=xfce-base/libxfce4util-4.17.2:=
+	>=xfce-base/xfconf-4.13.0:=
+	colord? ( >=x11-misc/colord-1.0.2:= )
+	libcanberra? ( >=media-libs/libcanberra-0.25[sound] )
+	upower? ( >=sys-power/upower-0.99.10 )
+
+	X? (
+		>=media-libs/fontconfig-2.6.0
+		>=x11-libs/libX11-1.6.7
+		>=x11-libs/libXcursor-1.1.0
+		>=x11-libs/libXi-1.2.0
+		>=x11-libs/libXrandr-1.5.0
+		input_devices_libinput? ( >=x11-drivers/xf86-input-libinput-0.6.0 )
+		libnotify? ( >=x11-libs/libnotify-0.7.8 )
+		xklavier? ( >=x11-libs/libxklavier-5.0 )
+	)
+	wayland? (
+		>=dev-libs/wayland-1.20
+		>=gui-libs/gtk-layer-shell-0.7.0
+	)
+"
+DEPEND="
+	${RDEPEND}
+	X? ( x11-base/xorg-proto )
+"
+# libxml2 for xmllint
+BDEPEND="
+	dev-libs/libxml2
+	dev-util/gdbus-codegen
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	python_fix_shebang dialogs/mime-settings/helpers/xfce4-compose-mail
+}
+
+src_configure() {
+	local myconf=(
+		$(use_enable upower upower-glib)
+		$(use_enable input_devices_libinput xorg-libinput)
+		$(use_enable libnotify)
+		$(use_enable colord)
+		$(use_enable xklavier libxklavier)
+		$(use_enable libcanberra sound-settings)
+		$(use_enable X x11)
+		$(use_enable wayland)
+	)
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}