1 files changed, 42 insertions, 0 deletions
diff --git a/app-misc/g15composer/g15composer-3.2.ebuild b/app-misc/g15composer/g15composer-3.2.ebuild
new file mode 100644
index 000000000000..8026fad9a88f
--- /dev/null
+++ b/app-misc/g15composer/g15composer-3.2.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=2
+inherit eutils
+
+DESCRIPTION="A library to render text and shapes into a buffer usable by the Logitech G15 keyboard"
+HOMEPAGE="http://g15tools.sourceforge.net/"
+SRC_URI="mirror://sourceforge/g15tools/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="truetype examples"
+
+DEPEND="app-misc/g15daemon
+	>=dev-libs/libg15render-1.2[truetype?]
+	truetype? ( media-libs/freetype )"
+
+src_configure() {
+	econf \
+		$(use_enable truetype ttf)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+
+	newinitd "${FILESDIR}/${P}.initd" ${PN}
+	newconfd "${FILESDIR}/${P}.confd" ${PN}
+
+	dodoc AUTHORS README ChangeLog
+
+	if use examples ; then
+		exeinto "/usr/share/${PN}"
+		doexe examples/*
+	fi
+}
+
+pkg_postinst() {
+	elog "Set the user to run g15composer in /etc/conf.d/g15composer before starting the service."
+}