1 files changed, 60 insertions, 0 deletions
diff --git a/app-text/zathura/zathura-0.5.2.ebuild b/app-text/zathura/zathura-0.5.2.ebuild
new file mode 100644
index 000000000000..a348aaac0cce
--- /dev/null
+++ b/app-text/zathura/zathura-0.5.2.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson virtualx xdg
+
+DESCRIPTION="A highly customizable and functional document viewer"
+HOMEPAGE="https://pwmt.org/projects/zathura/"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.pwmt.org/pwmt/${PN}.git"
+	EGIT_BRANCH="develop"
+else
+	SRC_URI="https://github.com/pwmt/zathura/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~riscv ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="ZLIB"
+SLOT="0"
+IUSE="doc seccomp sqlite synctex test"
+
+RESTRICT="!test? ( test )"
+
+DEPEND=">=dev-libs/girara-0.3.7
+	>=dev-libs/glib-2.50:2
+	>=sys-devel/gettext-0.19.8
+	x11-libs/cairo
+	>=x11-libs/gtk+-3.22:3
+	sys-apps/file
+	seccomp? ( sys-libs/libseccomp )
+	sqlite? ( >=dev-db/sqlite-3.5.9:3 )
+	synctex? ( app-text/texlive-core )"
+
+RDEPEND="${DEPEND}"
+
+BDEPEND="doc? ( dev-python/sphinx )
+	test? ( dev-libs/appstream-glib
+		dev-libs/check )
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/zathura-disable-seccomp-tests.patch
+)
+
+src_configure() {
+	local emesonargs=(
+		-Dconvert-icon=disabled
+		-Dmanpages=$(usex doc enabled disabled)
+		-Dseccomp=$(usex seccomp enabled disabled)
+		-Dsqlite=$(usex sqlite enabled disabled)
+		-Dsynctex=$(usex synctex enabled disabled)
+		)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}