1 files changed, 0 insertions, 67 deletions
diff --git a/dev-db/mycli/mycli-1.25.0-r1.ebuild b/dev-db/mycli/mycli-1.25.0-r1.ebuild
deleted file mode 100644
index 7adb613b75a5..000000000000
--- a/dev-db/mycli/mycli-1.25.0-r1.ebuild
+++ /dev/null
@@ -1,67 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_SINGLE_IMPL=yes
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{9..10} )
-
-inherit distutils-r1
-
-DESCRIPTION="CLI for MySQL Database with auto-completion and syntax highlighting"
-HOMEPAGE="
-	https://www.mycli.net/
-	https://github.com/dbcli/mycli/
-	https://pypi.org/project/mycli/
-"
-SRC_URI="
-	https://github.com/dbcli/mycli/archive/v${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="BSD MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="ssh"
-
-RDEPEND="
-	$(python_gen_cond_dep '
-		>=dev-python/cli_helpers-2.2.1[${PYTHON_USEDEP}]
-		>=dev-python/click-7.0[${PYTHON_USEDEP}]
-		>=dev-python/configobj-5.0.6[${PYTHON_USEDEP}]
-		>=dev-python/cryptography-1.0.0[${PYTHON_USEDEP}]
-		>=dev-python/prompt-toolkit-3.0.0[${PYTHON_USEDEP}]
-		<dev-python/prompt-toolkit-4.0.0[${PYTHON_USEDEP}]
-		dev-python/pyaes[${PYTHON_USEDEP}]
-		>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
-		>=dev-python/pymysql-0.9.2[${PYTHON_USEDEP}]
-		dev-python/pyperclip[${PYTHON_USEDEP}]
-		>=dev-python/sqlparse-0.3.0[${PYTHON_USEDEP}]
-		<dev-python/sqlparse-0.5.0[${PYTHON_USEDEP}]
-		ssh? ( dev-python/paramiko[${PYTHON_USEDEP}] )'
-	)
-"
-BDEPEND="
-	test? (
-		$(python_gen_cond_dep '
-			dev-python/mock[${PYTHON_USEDEP}]
-			dev-python/paramiko[${PYTHON_USEDEP}]
-		')
-	)
-"
-
-distutils_enable_tests pytest
-
-PATCHES=( "${FILESDIR}/mycli-1.21.1-fix-test-install.patch" )
-
-python_test() {
-	local EPYTEST_IGNORE=(
-		setup.py
-		mycli/magic.py
-		mycli/packages/parseutils.py
-		test/features
-		mycli/packages/paramiko_stub/__init__.py
-	)
-	epytest --capture=sys --doctest-modules --doctest-ignore-import-errors
-}