3 files changed, 66 insertions, 0 deletions
diff --git a/dev-python/pygtksourceview/Manifest b/dev-python/pygtksourceview/Manifest
new file mode 100644
index 000000000000..009ebf2ff409
--- /dev/null
+++ b/dev-python/pygtksourceview/Manifest
@@ -0,0 +1 @@
+DIST pygtksourceview-2.10.1.tar.bz2 290249 SHA256 b4b47c5aeb67a26141cb03663091dfdf5c15c8a8aae4d69c46a6a943ca4c5974 SHA512 6f8f35ba36cb26f256861ff7f14c3236cf566d6d02f3dea69f63844081caee969ad6288a2aa48d35d4eb542cda73da9d4bfe2cc57548ca15cd372011cab0276e WHIRLPOOL 237ce7a181c4508a17838cae28cf96fda6ebe4f16dbbbfdc83ca5da104a3422031369dbb870c7219f3031feded0833ac1393a6aabcb1fb45b169b198b3b480dc
diff --git a/dev-python/pygtksourceview/metadata.xml b/dev-python/pygtksourceview/metadata.xml
new file mode 100644
index 000000000000..7080c1467b4b
--- /dev/null
+++ b/dev-python/pygtksourceview/metadata.xml
@@ -0,0 +1,9 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<herd>gnome</herd>
+<!-- <herd>python</herd> -->
+<longdescription>
+Python bindings for gtksourceview (text editing widget)
+</longdescription>
+</pkgmetadata>
diff --git a/dev-python/pygtksourceview/pygtksourceview-2.10.1-r1.ebuild b/dev-python/pygtksourceview/pygtksourceview-2.10.1-r1.ebuild
new file mode 100644
index 000000000000..f6a7d5feecc3
--- /dev/null
+++ b/dev-python/pygtksourceview/pygtksourceview-2.10.1-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+GNOME_TARBALL_SUFFIX="bz2"
+PYTHON_COMPAT=( python2_7 )
+
+inherit gnome2 python-r1
+
+DESCRIPTION="GTK+2 bindings for Python"
+HOMEPAGE="http://www.pygtk.org/"
+
+LICENSE="LGPL-2.1"
+SLOT="2"
+KEYWORDS="alpha amd64 arm ia64 ~mips ppc ppc64 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="doc"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-python/pygobject-2.15.2:2[${PYTHON_USEDEP}]
+	>=dev-python/pygtk-2.8:2[${PYTHON_USEDEP}]
+	>=x11-libs/gtksourceview-2.9.7:2.0
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.10
+	virtual/pkgconfig
+	doc? (
+		dev-libs/libxslt
+		~app-text/docbook-xml-dtd-4.1.2
+		>=app-text/docbook-xsl-stylesheets-1.70.1 )
+"
+
+src_prepare() {
+	gnome2_src_prepare
+	python_copy_sources
+}
+
+src_configure() {
+	python_foreach_impl run_in_build_dir gnome2_src_configure $(use_enable doc docs)
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir gnome2_src_compile
+}
+
+src_test() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	DOCS="AUTHORS ChangeLog NEWS README"
+	python_foreach_impl run_in_build_dir gnome2_src_install
+}