1 files changed, 47 insertions, 0 deletions
diff --git a/dev-ruby/rspec-expectations/rspec-expectations-3.4.0.ebuild b/dev-ruby/rspec-expectations/rspec-expectations-3.4.0.ebuild
new file mode 100644
index 000000000000..03b80e8a0e0b
--- /dev/null
+++ b/dev-ruby/rspec-expectations/rspec-expectations-3.4.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+USE_RUBY="ruby20 ruby21 ruby22"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_EXTRADOC="Changelog.md README.md"
+
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A Behaviour Driven Development (BDD) framework for Ruby"
+HOMEPAGE="https://github.com/rspec/rspec-expectations"
+SRC_URI="https://github.com/rspec/${PN}/archive/v${PV}.tar.gz -> ${P}-git.tgz"
+
+LICENSE="MIT"
+SLOT="3"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc64"
+IUSE=""
+
+SUBVERSION="$(get_version_component_range 1-2)"
+
+ruby_add_rdepend ">=dev-ruby/diff-lcs-1.2.0 <dev-ruby/diff-lcs-2
+	=dev-ruby/rspec-support-${SUBVERSION}*"
+
+ruby_add_bdepend "test? (
+		>=dev-ruby/rspec-mocks-3.2.0:3
+	)"
+
+all_ruby_prepare() {
+	# Don't set up bundler: it doesn't understand our setup.
+	sed -i -e '/[Bb]undler/d' Rakefile || die
+
+	# Remove the Gemfile to avoid running through 'bundle exec'
+	rm -f Gemfile || die
+
+	# fix up the gemspecs
+	sed -i \
+		-e '/git ls/d' \
+		-e '/add_development_dependency/d' \
+		"${RUBY_FAKEGEM_GEMSPEC}" || die
+}