1 files changed, 45 insertions, 0 deletions
diff --git a/dev-util/goland/goland-2018.2.ebuild b/dev-util/goland/goland-2018.2.ebuild
new file mode 100644
index 000000000000..d46b730ae466
--- /dev/null
+++ b/dev-util/goland/goland-2018.2.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils
+
+SLOT=0
+
+SRC_URI="http://download.jetbrains.com/go/${P}.tar.gz"
+DESCRIPTION="Golang IDE by JetBrains"
+HOMEPAGE="http://www.jetbrains.com/go"
+
+KEYWORDS="~amd64"
+LICENSE="IDEA
+	|| ( IDEA_Academic IDEA_Classroom IDEA_OpenSource IDEA_Personal )"
+
+QA_PREBUILT="opt/${P}/*"
+
+S=${WORKDIR}/GoLand-${PV}
+
+RDEPEND="dev-lang/go"
+
+src_prepare() {
+	default
+	if ! use arm; then
+		rm -rf bin/fsnotifier-arm || die
+	fi
+}
+
+src_install() {
+	local dir="/opt/${P}"
+
+	insinto "${dir}"
+	doins -r *
+	fperms 755 "${dir}"/bin/{${PN}.sh,fsnotifier{,64}}
+
+	make_wrapper "${PN}" "${dir}/bin/${PN}.sh"
+	newicon "bin/${PN}.png" "${PN}.png"
+	make_desktop_entry "${PN}" "gogland" "${PN}" "Development;IDE;"
+
+	# recommended by: https://confluence.jetbrains.com/display/IDEADEV/Inotify+Watches+Limit
+	mkdir -p "${D}/etc/sysctl.d/" || die
+	echo "fs.inotify.max_user_watches = 524288" > "${D}/etc/sysctl.d/30-idea-inotify-watches.conf" || die
+}