1 files changed, 43 insertions, 0 deletions
diff --git a/kde-frameworks/sonnet/sonnet-5.73.0.ebuild b/kde-frameworks/sonnet/sonnet-5.73.0.ebuild
new file mode 100644
index 000000000000..f5798c21f8c1
--- /dev/null
+++ b/kde-frameworks/sonnet/sonnet-5.73.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_DESIGNERPLUGIN="true"
+QTMIN=5.14.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Framework for providing spell-checking through abstraction of popular backends"
+LICENSE="LGPL-2+ LGPL-2.1+"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="aspell +hunspell nls"
+
+BDEPEND="
+	nls? ( >=dev-qt/linguist-tools-${QTMIN}:5 )
+"
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	aspell? ( app-text/aspell )
+	hunspell? ( app-text/hunspell:= )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package aspell ASPELL)
+		$(cmake_use_find_package hunspell HUNSPELL)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# bugs: 680032
+	local myctestargs=(
+		-E "(sonnet-test_settings|sonnet-test_highlighter)"
+	)
+
+	ecm_src_test
+}