1 files changed, 75 insertions, 0 deletions
diff --git a/media-gfx/mcomix/mcomix-1.3.0_pre20211015.ebuild b/media-gfx/mcomix/mcomix-1.3.0_pre20211015.ebuild
new file mode 100644
index 000000000000..095d015ca001
--- /dev/null
+++ b/media-gfx/mcomix/mcomix-1.3.0_pre20211015.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit desktop python-r1 xdg
+
+# Hash used for this version
+GIT_PV="483f4b3f2d9a125606d47597ae7eff3b38e5bf9d"
+
+DESCRIPTION="GTK image viewer for comic book archives"
+HOMEPAGE="https://github.com/multiSnow/mcomix3"
+SRC_URI="https://github.com/multiSnow/mcomix3/archive/${GIT_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE=""
+
+DEPEND="${PYTHON_DEPS}"
+RDEPEND="${DEPEND}
+	virtual/jpeg
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pygobject[${PYTHON_USEDEP}]
+	!media-gfx/comix"
+BDEPEND="sys-devel/gettext"
+
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+S=${WORKDIR}/mcomix3-${GIT_PV}
+
+src_prepare() {
+	default
+
+	for file in mcomix/mcomix/messages/*/LC_MESSAGES/*po
+	do
+		msgfmt ${file} -o ${file/po/mo} || die
+		rm ${file} || die
+	done
+}
+
+src_install() {
+	python_foreach_impl python_domodule mcomix/mcomix
+	python_foreach_impl python_newscript mcomix/mcomixstarter.py mcomix
+
+	for size in 16 22 24 32 48
+	do
+		doicon -s ${size} \
+			mime/icons/${size}x${size}/*png \
+			mcomix/mcomix/images/${size}x${size}/mcomix.png
+	done
+	doicon mcomix/mcomix/images/mcomix.png
+	domenu mime/mcomix.desktop
+	doman man/mcomix.1
+
+	insinto /usr/share/metainfo
+	doins mime/mcomix.appdata.xml
+
+	dodoc README.rst TODO
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	echo
+	elog "Additional packages are required to open the most common comic archives:"
+	elog
+	elog "    cbr: app-arch/unrar"
+	elog "    cbz: app-arch/unzip"
+	elog
+	elog "You can also add support for 7z or LHA archives by installing"
+	elog "app-arch/p7zip or app-arch/lha. Install app-text/mupdf for"
+	elog "pdf support."
+	echo
+}