1 files changed, 58 insertions, 0 deletions
diff --git a/media-sound/aumix/aumix-2.9.1-r1.ebuild b/media-sound/aumix/aumix-2.9.1-r1.ebuild
new file mode 100644
index 000000000000..d5b77c03df8d
--- /dev/null
+++ b/media-sound/aumix/aumix-2.9.1-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools desktop
+
+DESCRIPTION="Aumix volume/mixer control program"
+HOMEPAGE="http://jpj.net/~trevor/aumix.html"
+SRC_URI="http://jpj.net/~trevor/aumix/releases/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm ~hppa ~mips ppc ppc64 sparc x86"
+IUSE="gpm gtk nls"
+
+RDEPEND="sys-libs/ncurses:0=
+	gpm? ( sys-libs/gpm )
+	gtk? ( x11-libs/gtk+:2 )
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-tinfo.patch #578722
+	"${FILESDIR}"/${P}-fno-common.patch
+	"${FILESDIR}"/${P}-gcc14-build-fix.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf #578722
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable nls)
+		$(usex gtk '' --without-gtk)
+		$(usex gpm '' --without-gpm)
+		--without-sysmouse #921162
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	newinitd "${FILESDIR}"/aumix.rc6 aumix
+
+	if use gtk; then
+		doicon data/aumix.xpm
+		make_desktop_entry aumix Aumix
+	fi
+}