1 files changed, 118 insertions, 0 deletions
diff --git a/net-analyzer/gvmd/gvmd-21.4.5.ebuild b/net-analyzer/gvmd/gvmd-21.4.5.ebuild
new file mode 100644
index 000000000000..4d133ecc4f04
--- /dev/null
+++ b/net-analyzer/gvmd/gvmd-21.4.5.ebuild
@@ -0,0 +1,118 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_MAKEFILE_GENERATOR="emake"
+inherit cmake systemd toolchain-funcs
+
+DESCRIPTION="Greenbone vulnerability manager, previously named openvas-manager"
+HOMEPAGE="https://www.greenbone.net/en/ https://github.com/greenbone/gvmd/"
+SRC_URI="https://github.com/greenbone/gvmd/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+SLOT="0"
+LICENSE="GPL-2+"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	acct-group/gvm
+	acct-user/gvm
+	app-crypt/gpgme:1=
+	dev-db/postgresql:*[uuid]
+	dev-libs/glib:2
+	dev-libs/libical:=
+	>=net-analyzer/gvm-libs-21.4.4
+	net-libs/gnutls:=[tools]
+	doc?   (
+		app-text/xmlstarlet
+		dev-texlive/texlive-latexextra )
+"
+RDEPEND="
+	${DEPEND}
+	net-analyzer/ospd-openvas
+"
+BDEPEND="
+	sys-devel/bison
+	sys-devel/flex
+	virtual/pkgconfig
+	doc? (
+		app-doc/doxygen[dot]
+		app-doc/xmltoman
+		app-text/htmldoc
+		dev-libs/libxslt
+	)
+	test? ( dev-libs/cgreen )
+"
+
+src_prepare() {
+	cmake_src_prepare
+	# QA-Fix | Use correct FHS/Gentoo policy paths for 9.0.0
+	sed -i -e "s*share/doc/gvm/html/*share/doc/gvmd-${PV}/html/*g" doc/CMakeLists.txt || die
+	sed -i -e "s*/doc/gvm/*/doc/gvmd-${PV}/*g" CMakeLists.txt || die
+	# QA-Fix | Remove !CLANG Doxygen warnings for 9.0.0
+	if use doc; then
+		if ! tc-is-clang; then
+		   local f
+		   for f in doc/*.in
+		   do
+			sed -i \
+				-e "s*CLANG_ASSISTED_PARSING = NO*#CLANG_ASSISTED_PARSING = NO*g" \
+				-e "s*CLANG_OPTIONS*#CLANG_OPTIONS*g" \
+				"${f}" || die "couldn't disable CLANG parsing"
+		   done
+		fi
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		"-DLOCALSTATEDIR=${EPREFIX}/var"
+		"-DSYSCONFDIR=${EPREFIX}/etc"
+		"-DLIBDIR=${EPREFIX}/usr/$(get_libdir)"
+		"-DSBINDIR=${EPREFIX}/usr/bin"
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	if use doc; then
+		cmake_build -C "${BUILD_DIR}" doc
+		cmake_build doc-full -C "${BUILD_DIR}" doc
+	fi
+	if use test; then
+		cmake_build tests
+	fi
+	cmake_build rebuild_cache
+}
+
+src_install() {
+	if use doc; then
+		local HTML_DOCS=( "${BUILD_DIR}"/doc/generated/html/. )
+	fi
+	cmake_src_install
+
+	insinto /etc/gvm/sysconfig
+	doins "${FILESDIR}/${PN}-daemon.conf"
+
+	exeinto /etc/gvm
+	newexe "${FILESDIR}"/${P}-startpre.sh gvmd-startpre.sh
+
+	fowners -R gvm:gvm /etc/gvm
+
+	newinitd "${FILESDIR}/${P}.init" "${PN}"
+	newconfd "${FILESDIR}/${PN}-daemon.conf" "${PN}"
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/${PN}.logrotate" "${PN}"
+
+	systemd_dounit "${FILESDIR}/${PN}.service"
+
+	# Set proper permissions on required files/directories
+	keepdir /var/lib/gvm/gvmd
+	fowners -R gvm:gvm /var/lib/gvm
+
+	rm -r "${D}/run" || die
+}