2 files changed, 86 insertions, 0 deletions
diff --git a/sci-libs/indilib/Manifest b/sci-libs/indilib/Manifest
index 41262b171751..bc92445ce3c2 100644
--- a/sci-libs/indilib/Manifest
+++ b/sci-libs/indilib/Manifest
@@ -1 +1,2 @@
 DIST indilib-1.9.8.tar.gz 2633085 BLAKE2B 045d38fc565546528fddfa83cfd78650d30e41769923d7ec8f462a617fdd298228913a075a9f0b511867aa9174143da010bbb4c015d8b5a1d51f2b80090e50d5 SHA512 b9551547de277fe311e4779e65915351850a25fb049ddcfad634ef385014b521416f2366cf50cda80cdfa4a754c18face21cfd59f7f45c4018ca733ddf981ab2
+DIST indilib-1.9.9.tar.gz 2658593 BLAKE2B a35e410bf48bc404bf39e0a32f6536cf882328ae840800593a54676c5c7c0f28852597555fd4ce968e8a10b7e8cabe898a4c19e4490a6078a80215db1dea4282 SHA512 1684b70fb2cb796be315ac3cb46b18efca1e76803f508e2b435416cadc9b8930acc0333b01d97352a429296ac9abdf0d54cd8ed21171aa47315148a48a9bede6
diff --git a/sci-libs/indilib/indilib-1.9.9.ebuild b/sci-libs/indilib/indilib-1.9.9.ebuild
new file mode 100644
index 000000000000..48d99ce5b75b
--- /dev/null
+++ b/sci-libs/indilib/indilib-1.9.9.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake udev
+
+DESCRIPTION="INDI Astronomical Control Protocol library"
+HOMEPAGE="https://www.indilib.org/"
+SRC_URI="https://github.com/${PN}/${PN/lib/}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${P/lib/}"
+
+LICENSE="BSD GPL-2+ LGPL-2+ LGPL-2.1+"
+SLOT="0/1"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="ogg rtlsdr test websocket"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/libev
+	media-libs/libjpeg-turbo:=
+	net-misc/curl
+	sci-libs/cfitsio:=
+	sci-libs/fftw:3.0=
+	sci-libs/gsl:=
+	sci-libs/libnova:=
+	sys-libs/zlib
+	virtual/libusb:1
+	ogg? (
+		media-libs/libogg
+		media-libs/libtheora
+	)
+	rtlsdr? ( net-wireless/rtl-sdr )
+	websocket? ( dev-libs/boost:= )
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-kernel/linux-headers )
+	test? ( >=dev-cpp/gtest-1.8.0 )
+	websocket? ( dev-cpp/websocketpp )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DINDI_BUILD_QT5_CLIENT=OFF
+		-DUDEVRULES_INSTALL_DIR="${EPREFIX}$(get_udevdir)"/rules.d
+		$(cmake_use_find_package ogg OggTheora)
+		$(cmake_use_find_package rtlsdr RTLSDR)
+		-DINDI_BUILD_UNITTESTS=$(usex test)
+		-DINDI_BUILD_INTEGTESTS=$(usex test)
+		-DINDI_BUILD_WEBSOCKET=$(usex websocket)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	local myctestargs=()
+
+	if use ppc || use ppc64 || use sparc ; then
+		# Broken on big endian for quite some time.
+		# Reported upstream: file needs to be replaced w/ a normal library
+		# for b64.
+		# bug #763126
+		myctestargs+=(
+			-E "(test_base64)"
+		)
+	fi
+
+	# Unit tests
+	BUILD_DIR="${BUILD_DIR}"/test cmake_src_test
+
+	# Integration tests
+	# They fail in parallel because they try to bind to the same port more
+	# than once.
+	BUILD_DIR="${BUILD_DIR}"/integs cmake_src_test -j1
+}
+
+pkg_postinst() {
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}