app-misc/ttyload/ttyload-0.5.3-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit toolchain-funcs

DESCRIPTION="color-coded graph of load averages over time"
HOMEPAGE="https://www.daveltd.com/src/util/ttyload https://github.com/lindes/ttyload"
SRC_URI="https://www.daveltd.com/src/util/${PN}/${P}.tar.bz2"

KEYWORDS="amd64 x86"
LICENSE="ISC"
SLOT="0"

DEPEND="sys-libs/ncurses:0="

RESTRICT="test"

DOCS=( BUGS HISTORY LICENSE README.md TODO )

src_prepare() {
	default

	eapply "${FILESDIR}/ttyload-0.5.3-fix-sigabrt-in-strcpy.patch"

	sed -i '10i#include <time.h>' "${PN}.h" || die

	sed -e "s#make#$\(MAKE\)#" \
		-e "s#^CFLAGS.*#CFLAGS=\$(INCLUDES) ${CFLAGS} \$(VERSION)#" \
		-i Makefile || die
}

src_compile() {
	emake CC="$(tc-getCC)" LDFLAGS="${LDFLAGS}"
}

src_install() {
	dobin "${PN}"
	doman "${PN}.1"
	einstalldocs
}