blob: d6a93da72c86a5510f5b3ad5517e47c372869412 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI="6"
inherit libtool multilib-minimal usr-ldscript
DESCRIPTION="GNU charset conversion library for libc which doesn't implement it"
HOMEPAGE="https://www.gnu.org/software/libiconv/"
SRC_URI="mirror://gnu/libiconv/${P}.tar.gz"
LICENSE="LGPL-2+ GPL-3+"
SLOT="0"
KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~ia64 ~m68k ~mips ppc ~ppc64 ~s390 ~sparc x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
IUSE="prefix static-libs"
DEPEND="!sys-libs/glibc
!sys-libs/musl
!userland_GNU? ( !sys-apps/man-pages )"
RDEPEND="${DEPEND}"
PATCHES=(
"${FILESDIR}/${PN}-1.15-no-gets.patch"
"${FILESDIR}/${PN}-1.15-no-aix-tweaks.patch"
)
src_prepare() {
default
elibtoolize
}
multilib_src_configure() {
if use prefix ; then
# In Prefix we want to have the same header declaration on every
# platform, so make configure find that it should do
# "const char * *inbuf"
export am_cv_func_iconv=no
fi
# Disable NLS support because that creates a circular dependency
# between libiconv and gettext
ECONF_SOURCE="${S}" \
econf \
--docdir="\$(datarootdir)/doc/${PF}/html" \
--disable-nls \
--enable-shared \
$(use_enable static-libs static)
}
multilib_src_install_all() {
use static-libs || find "${ED}" -name 'lib*.la' -delete
# Install in /lib as utils installed in /lib like gnutar
# can depend on this
gen_usr_ldscript -a iconv charset
# If we have a GNU userland, we probably have sys-apps/man-pages
# installed, which means we want to rename our copies #503162.
# The use of USELAND=GNU is kind of a hack though ...
if use userland_GNU ; then
cd "${ED}"/usr/share/man || die
local f
for f in man*/*.[0-9] ; do
mv "${f}" "${f%/*}/${PN}-${f#*/}" || die
done
fi
}
|
GitWeb
