blob: bcbb3f9c90c21e38a7242525451bd8fd2b25a532 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
DESCRIPTION="OCaml tool to find/use non-standard packages"
HOMEPAGE="http://projects.camlcity.org/projects/findlib.html"
SRC_URI="http://download.camlcity.org/download/${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ppc64 x86 ~amd64-linux ~x86-linux ~ppc-macos"
IUSE="doc +ocamlopt tk"
DEPEND=">=dev-lang/ocaml-4.02.3-r1:=[ocamlopt?]
tk? ( dev-ml/labltk:= )"
RDEPEND="${DEPEND}"
QA_FLAGS_IGNORED='.*'
PATCHES=( "${FILESDIR}"/externalmeta7.patch )
src_prepare() {
default
export ocamlfind_destdir="${EPREFIX}/usr/$(get_libdir)/ocaml"
export stublibs="${ocamlfind_destdir}/stublibs"
}
src_configure() {
local myconf
use tk && myconf="-with-toolbox"
./configure -bindir "${EPREFIX}"/usr/bin -mandir "${EPREFIX}"/usr/share/man \
-sitelib ${ocamlfind_destdir} \
-config ${ocamlfind_destdir}/findlib/findlib.conf \
-no-custom \
${myconf} || die "configure failed"
}
src_compile() {
emake -j1 all
if use ocamlopt; then
emake -j1 opt # optimized code
fi
}
src_install() {
emake prefix="${D}" install
dodir "${stublibs#${EPREFIX}}"
if use doc; then
cd "${S}/doc" || die
dodoc QUICKSTART README DOCINFO
docinto html
dodoc -r ref-html guide-html
fi
}
check_stublibs() {
local ocaml_stdlib=`ocamlc -where`
local ldconf="${ocaml_stdlib}/ld.conf"
if [ ! -e ${ldconf} ]
then
echo "${ocaml_stdlib}" > ${ldconf}
echo "${ocaml_stdlib}/stublibs" >> ${ldconf}
fi
if [ -z `grep -e ${stublibs} ${ldconf}` ]
then
echo ${stublibs} >> ${ldconf}
fi
}
pkg_postinst() {
check_stublibs
}
|
GitWeb