blob: 1c237256715b9419e54af1551888044e6a99fdf7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=poetry
PYTHON_COMPAT=( python3_{9..11} )
inherit distutils-r1
DESCRIPTION="A python utility/library to sort imports"
HOMEPAGE="
https://github.com/PyCQA/isort/
https://pypi.org/project/isort/
"
SRC_URI="
https://github.com/PyCQA/isort/archive/${PV}.tar.gz
-> ${P}.gh.tar.gz
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
RDEPEND="
dev-python/tomli[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
dev-python/black[${PYTHON_USEDEP}]
dev-python/colorama[${PYTHON_USEDEP}]
dev-python/hypothesis[${PYTHON_USEDEP}]
dev-python/natsort[${PYTHON_USEDEP}]
dev-python/pylama[${PYTHON_USEDEP}]
dev-python/pytest-mock[${PYTHON_USEDEP}]
dev-vcs/git
)
"
distutils_enable_tests pytest
src_prepare() {
# unbundle tomli
sed -i -e 's:from ._vendored ::' isort/settings.py || die
rm -r isort/_vendored || die
# leftover toml import used to determine .toml support
sed -i -e 's:import toml:toml = True:' tests/unit/test_isort.py || die
distutils-r1_src_prepare
}
python_test() {
cp -a "${BUILD_DIR}"/{install,test} || die
local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
# Install necessary plugins
local p
for p in example*/; do
pushd "${p}" >/dev/null || die
distutils_pep517_install "${BUILD_DIR}"/test
popd >/dev/null || die
done
local EPYTEST_IGNORE=(
# Excluded from upstream's test script
tests/unit/test_deprecated_finders.py
)
epytest tests/unit
}
|
GitWeb
