dev-python/jq/jq-1.7.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Copyright 2021-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..12} )

inherit distutils-r1

MY_P="jq.py-${PV}"
DESCRIPTION="Python bindings for jq"
HOMEPAGE="
	https://github.com/mwilliamson/jq.py/
	https://pypi.org/project/jq/
"
# pypi sdist is missing .pyx
SRC_URI="
	https://github.com/mwilliamson/jq.py/archive/${PV}.tar.gz
		-> ${MY_P}.gh.tar.gz
"
S=${WORKDIR}/${MY_P}

LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"

# Minimum versions of jq + onigurama are from setup.py's bundled versions
DEPEND="
	>=app-misc/jq-1.7.1:=
	>=dev-libs/oniguruma-6.9.8:=
"
RDEPEND="
	${DEPEND}
"
BDEPEND="
	dev-python/cython[${PYTHON_USEDEP}]
"

distutils_enable_tests pytest

python_compile() {
	local -x JQPY_USE_SYSTEM_LIBS=1

	# Cython compilation isn't part of setup.py, so do it manually
	"${EPYTHON}" -m cython -3 jq.pyx -o jq.c || die
	distutils-r1_python_compile
}