blob: 2fc83ec82518203a074fff7e4c2ac5220252fa33 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python2_7 python3_{5,6,7} pypy pypy3 )
inherit distutils-r1
DESCRIPTION="package to manage versions by scm tags via setuptools"
HOMEPAGE="https://github.com/pypa/setuptools_scm https://pypi.org/project/setuptools_scm/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
IUSE="test"
RESTRICT="!test? ( test )"
DEPEND="
dev-python/setuptools[${PYTHON_USEDEP}]
test? (
dev-python/pytest[${PYTHON_USEDEP}]
dev-vcs/git
dev-vcs/mercurial )"
python_prepare_all() {
# network access
sed -i -e 's:test_pip_download:_&:' testing/test_regressions.py || die
# all fetch specific setuptools versions
rm testing/test_setuptools_support.py || die
# remove self-dependency
sed -i -e "/arguments\.update/s@scm_config()@{'version': '${PV}'}@" \
-e "/__main__/i del sys.path[0]" setup.py || die
distutils-r1_python_prepare_all
}
python_test() {
PYTHONPATH= distutils_install_for_testing
py.test -v -v -x || die "Tests fail with ${EPYTHON}"
}
python_install() {
PYTHONPATH= distutils-r1_python_install
}
|
GitWeb
