blob: 344b909293da4640b79a7064010c1f45b6f26032 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
USE_RUBY="ruby21 ruby22 ruby23"
RUBY_FAKEGEM_TASK_TEST="test:regular"
RUBY_FAKEGEM_TASK_DOC=""
RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.rdoc"
RUBY_FAKEGEM_GEMSPEC="railties.gemspec"
RUBY_FAKEGEM_BINWRAP=""
inherit ruby-fakegem versionator
DESCRIPTION="Tools for creating, working with, and running Rails applications"
HOMEPAGE="https://github.com/rails/rails"
SRC_URI="https://github.com/rails/rails/archive/v${PV}.tar.gz -> rails-${PV}.tgz"
LICENSE="MIT"
SLOT="$(get_version_component_range 1-2)"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux"
IUSE=""
RUBY_S="rails-${PV}/${PN}"
# The test suite has many failures, most likely due to a mismatch in
# exact dependencies or environment specifics. Needs further
# investigation.
RESTRICT="test"
RDEPEND+=">=app-eselect/eselect-rails-0.21"
ruby_add_rdepend "
~dev-ruby/activesupport-${PV}
~dev-ruby/actionpack-${PV}
>=dev-ruby/thor-0.18.1 <dev-ruby/thor-2
>=dev-ruby/rake-0.8.7"
ruby_add_bdepend "
test? (
~dev-ruby/actionview-${PV}
dev-ruby/mocha:0.14
)"
all_ruby_prepare() {
rm "${S}/../Gemfile" || die "Unable to remove Gemfile"
sed -i -e '/load_paths/d' test/abstract_unit.rb || die "Unable to remove load paths"
sed -i -e '1igem "minitest", "~>4.0"' test/abstract_unit.rb || die
# Also allow rdoc 4.x
sed -i -e 's/~> 3.4/>= 3.4/' ${RUBY_FAKEGEM_GEMSPEC} || die
}
all_ruby_install() {
all_fakegem_install
ruby_fakegem_binwrapper rails rails-${PV}
}
pkg_postinst() {
elog "To select between slots of rails, use:"
elog "\teselect rails"
eselect rails update
}
pkg_postrm() {
eselect rails update
}
|
GitWeb
