dev-ruby/rb-gsl/rb-gsl-2.1.0.2-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

# No >= ruby30 because of https://github.com/SciRuby/rb-gsl/issues/63
USE_RUBY="ruby26 ruby27"

RUBY_FAKEGEM_NAME="gsl"
inherit ruby-fakegem multilib

RUBY_FAKEGEM_RECIPE_DOC="rdoc"
RUBY_FAKEGEM_EXTRADOC="ChangeLog README.md"

RUBY_FAKEGEM_EXTENSIONS=(ext/gsl_native/extconf.rb)

DESCRIPTION="Ruby interface to GNU Scientific Library"
HOMEPAGE="https://github.com/SciRuby/rb-gsl"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm64"
IUSE="doc"

DEPEND+=" >=sci-libs/gsl-2.3[deprecated]"
RDEPEND+=" >=sci-libs/gsl-2.3[deprecated]"

RUBY_S="${PN}-${P}"

ruby_add_bdepend "dev-ruby/narray"
ruby_add_rdepend "dev-ruby/narray"

all_ruby_prepare() {
	sed -i -e '/LOCAL_LIBS/ s: -l: -L#{path.gsub("ext", "lib")} -l:' ext/gsl_native/extconf.rb || die
	# nmatrix only tests
	rm -r test/gsl/nmatrix_tests || die
}

each_ruby_configure() {
	NARRAY=1 each_fakegem_configure
}

each_ruby_compile() {
	NARRAY=1 each_fakegem_compile
}

each_ruby_test() {
	NARRAY=1 ${RUBY} -Ilib:test:. -e 'Dir["test/**/*_test.rb"].each{|f| require f}' || die
}