blob: 0cc27f52b04e78c0facdc8b0beceee771005908f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} )
VALA_USE_DEPEND="vapigen"
inherit gnome.org meson python-any-r1 vala xdg
DESCRIPTION="A framework for easy media discovery and browsing"
HOMEPAGE="https://wiki.gnome.org/Projects/Grilo"
LICENSE="LGPL-2.1+"
SLOT="0.3/0" # subslot is libgrilo-0.3 soname suffix
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="gtk gtk-doc +introspection +network +playlist vala"
REQUIRED_USE="vala? ( introspection )"
# oauth could be optional if meson is patched - used for flickr oauth in grilo-test-ui tool
RDEPEND="
>=dev-libs/glib-2.44:2
dev-libs/libxml2:2
network? ( >=net-libs/libsoup-2.41.3:2.4[introspection?] )
playlist? ( >=dev-libs/totem-pl-parser-3.4.1 )
introspection? ( >=dev-libs/gobject-introspection-1.54:= )
gtk? (
net-libs/liboauth
>=x11-libs/gtk+-3.14:3 )
"
DEPEND="${RDEPEND}
dev-util/glib-utils
>=sys-devel/gettext-0.19.8
virtual/pkgconfig
gtk-doc? (
>=dev-util/gtk-doc-1.10
app-text/docbook-xml-dtd:4.3 )
${PYTHON_DEPS}
vala? ( $(vala_depend) )
"
src_prepare() {
sed -i -e "s:'GETTEXT_PACKAGE', meson.project_name():'GETTEXT_PACKAGE', 'grilo-${SLOT%/*}':" meson.build || die
sed -i -e "s:meson.project_name():'grilo-${SLOT%/*}':" po/meson.build || die
sed -i -e "s:'grilo':'grilo-${SLOT%/*}':" doc/grilo/meson.build || die
# Drop explicit unversioned vapigen check
sed -i -e "/vapigen.*=.*find_program/d" meson.build || die
# Don't build examples; they get embedded in gtk-doc, thus we don't install the sources with USE=examples either
sed -i -e "/subdir('examples')/d" meson.build || die
xdg_src_prepare
use vala && vala_src_prepare
}
src_configure() {
local emesonargs=(
$(meson_use network enable-grl-net)
$(meson_use playlist enable-grl-pls)
$(meson_use gtk-doc enable-gtk-doc)
$(meson_use introspection enable-introspection)
$(meson_use gtk enable-test-ui)
$(meson_use vala enable-vala)
)
meson_src_configure
}
|
GitWeb
