blob: c2f08f49bcb8707687eb273634b2370d911f2743 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit cmake
MY_PN=libLASi
MY_P=${MY_PN}-${PV}
DESCRIPTION="C++ library for postscript stream output"
HOMEPAGE="http://www.unifont.org/lasi"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
LICENSE="GPL-2"
SLOT="0/2"
KEYWORDS="~alpha amd64 ~arm64 hppa ~mips ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux"
IUSE="doc examples"
RDEPEND="
dev-libs/glib:2
media-libs/freetype:2
x11-libs/pango"
DEPEND="${RDEPEND}"
BDEPEND="
virtual/pkgconfig
doc? ( app-doc/doxygen )"
S="${WORKDIR}/${MY_P}"
PATCHES=(
"${FILESDIR}"/${P}-cmake.patch
"${FILESDIR}"/${P}-pkgconfig.patch
)
src_prepare() {
cmake_src_prepare
sed -i \
-e "s:\/lib$:\/$(get_libdir):" \
-e "s/libLASi-\${VERSION}/${PF}/" \
cmake/modules/instdirs.cmake || die
sed -i \
-e "s:\${DATA_DIR}/examples:/usr/share/doc/${PF}/examples:" \
examples/CMakeLists.txt || die
if use !examples; then
sed -i -e '/add_subdirectory(examples)/d' CMakeLists.txt || die
fi
}
src_configure() {
# doesn't like CMAKE_BUILD_TYPE = Gentoo
CMAKE_BUILD_TYPE=None
local mycmakeargs=(
-DDOXYGEN_EXECUTABLE=$(usex doc "${BROOT}"/usr/bin/doxygen '')
-DUSE_RPATH=OFF
)
cmake_src_configure
}
|
GitWeb
