blob: 88dfc6c7e3b75fce82636f9967a6ff77440bb763 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools
DESCRIPTION="featureful ncurses based MPD client inspired by ncmpc"
HOMEPAGE="
https://rybczak.net/ncmpcpp/
https://github.com/ncmpcpp/ncmpcpp/
"
SRC_URI="https://rybczak.net/ncmpcpp/stable/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc x86"
IUSE="clock outputs taglib visualizer"
RDEPEND="
>=media-libs/libmpdclient-2.1
dev-libs/boost:=[icu,nls]
dev-libs/icu:=
net-misc/curl
sys-libs/ncurses:=[unicode(+)]
sys-libs/readline:=
taglib? ( media-libs/taglib )
visualizer? ( sci-libs/fftw:3.0= )
"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
PATCHES=(
"${FILESDIR}/${PN}-taglib-pc.patch"
)
src_prepare() {
default
eautoreconf
sed -i -e '/^docdir/d' {,doc/}Makefile{.am,.in} || die
sed -i -e 's|COPYING||g' Makefile{.am,.in} || die
}
src_configure() {
# --with-lto only appends -flto
econf \
$(use_enable clock) \
$(use_enable outputs) \
$(use_enable visualizer) \
--without-lto \
$(use_with taglib) \
$(use_with visualizer fftw)
}
src_install() {
default
dodoc doc/{bindings,config}
}
pkg_postinst() {
echo
elog "Example configuration files have been installed at"
elog "${EROOT}/usr/share/doc/${PF}"
elog "${P} uses ~/.ncmpcpp/config and ~/.ncmpcpp/bindings"
elog "as user configuration files."
echo
if use visualizer; then
elog "If you want to use the visualizer, you need mpd with fifo enabled."
echo
fi
}
|
GitWeb
