blob: 3cf06cfdf4c39c1574b5c02b8fad9a0064d13c7d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit autotools multilib-minimal ltprune
DESCRIPTION="A system-independent library for user-level network packet capture"
HOMEPAGE="
https://www.tcpdump.org/
https://github.com/the-tcpdump-group/libpcap
"
SRC_URI="
https://github.com/the-tcpdump-group/${PN}/archive/${P/_}.tar.gz
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 ~riscv s390 ~sh sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
IUSE="bluetooth dbus netlink static-libs usb"
RDEPEND="
bluetooth? ( net-wireless/bluez:=[${MULTILIB_USEDEP}] )
dbus? ( sys-apps/dbus[${MULTILIB_USEDEP}] )
netlink? ( dev-libs/libnl:3[${MULTILIB_USEDEP}] )
"
DEPEND="
${RDEPEND}
sys-devel/flex
virtual/yacc
dbus? ( virtual/pkgconfig[${MULTILIB_USEDEP}] )
"
S=${WORKDIR}/${PN}-${P/_}
PATCHES=(
"${FILESDIR}"/${PN}-1.8.1-usbmon.patch
"${FILESDIR}"/${PN}-1.9.0-pcap-config-includedir.patch
)
src_prepare() {
default
echo ${PV} > VERSION || die
eautoreconf
}
multilib_src_configure() {
ECONF_SOURCE="${S}" \
econf \
$(use_enable bluetooth) \
$(use_enable dbus) \
$(use_enable usb) \
$(use_with netlink libnl) \
--disable-rdma \
--enable-ipv6
}
multilib_src_compile() {
emake all shared
}
multilib_src_install_all() {
dodoc CREDITS CHANGES VERSION TODO README.* doc/README.*
# remove static libraries (--disable-static does not work)
if ! use static-libs; then
find "${ED}" -name '*.a' -exec rm {} + || die
fi
prune_libtool_files
# We need this to build pppd on G/FBSD systems
if [[ "${USERLAND}" == "BSD" ]]; then
insinto /usr/include
doins pcap-int.h portability.h
fi
}
|
GitWeb