blob: 5336e7de9c0642f8ff35b4a9e362d07606a0c48f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
if [[ ${PV} == "9999" ]] ; then
inherit git-r3
EGIT_REPO_URI="https://gitlab.freedesktop.org/mobile-broadband/libqmi.git"
else
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~x86"
SRC_URI="https://gitlab.freedesktop.org/mobile-broadband/libqmi/-/archive/${PV}/${P}.tar.bz2"
fi
inherit bash-completion-r1 meson udev
DESCRIPTION="Qualcomm MSM (Mobile Station Modem) Interface (QMI) modem protocol library"
HOMEPAGE="https://www.freedesktop.org/wiki/Software/libqmi/ https://gitlab.freedesktop.org/mobile-broadband/libqmi"
LICENSE="LGPL-2"
IUSE="gtk-doc +mbim +qrtr"
SLOT="0/5.9" # soname of libqmi-glib.so
RDEPEND="
>=dev-libs/glib-2.56
>=dev-libs/libgudev-232
mbim? ( >=net-libs/libmbim-1.18.0 )
qrtr? ( >=net-libs/libqrtr-glib-1.0.0:= )
dev-libs/gobject-introspection:=
"
DEPEND="${RDEPEND}"
BDEPEND="
sys-apps/help2man
virtual/pkgconfig
gtk-doc? ( dev-util/gtk-doc )
"
src_configure() {
# Let's avoid BuildRequiring bash-completion, install it manually
local emesonargs=(
$(meson_use mbim mbim_qmux)
$(meson_use qrtr)
-Drmnet=true
-Dudev=true
-Dudevdir="$(get_udevdir)"
-Dintrospection=true
$(meson_use gtk-doc gtk_doc)
-Dman=true
-Dbash_completion=false
)
meson_src_configure
}
src_install() {
meson_src_install
dobashcomp src/qmicli/qmicli
}
|
GitWeb
