blob: bbe1e160f1c0f1acdafd9e0b281064faf2f12cdb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DOCS_BUILDER="sphinx"
DOCS_DIR="doc"
DOCS_AUTODOC=0
PYTHON_COMPAT=( python3_{10..13} )
# python-any-r1 is inherited first because docs.eclass sources it, and cmake.eclass exports phases.
inherit python-any-r1 cmake docs linux-info
DESCRIPTION="UPnP Media Server"
HOMEPAGE="https://gerbera.io"
if [[ ${PV} == 9999 ]]; then
EGIT_REPO_URI="https://github.com/gerbera/${PN}.git"
inherit git-r3
else
SRC_URI="https://github.com/gerbera/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/${P}"
KEYWORDS="~amd64 ~arm ~arm64 ~x86"
fi
LICENSE="GPL-2"
SLOT="0"
IUSE="curl debug doc +exif exiv2 +ffmpeg ffmpegthumbnailer +javascript +magic +matroska mysql systemd +taglib"
RDEPEND="
acct-group/gerbera
acct-user/gerbera
dev-db/sqlite
dev-libs/libebml:=
dev-libs/libfmt:=
dev-libs/pugixml
dev-libs/spdlog:=
net-libs/libupnp:=[ipv6(+),reuseaddr,-blocking-tcp]
sys-apps/util-linux
sys-libs/zlib
virtual/libiconv
curl? ( net-misc/curl )
exif? ( media-libs/libexif )
exiv2? ( media-gfx/exiv2:= )
ffmpeg? ( media-video/ffmpeg:= )
ffmpegthumbnailer? ( media-video/ffmpegthumbnailer[png] )
javascript? ( dev-lang/duktape:= )
magic? ( sys-apps/file )
matroska? ( media-libs/libmatroska:= )
mysql? ( dev-db/mysql-connector-c:= )
taglib? ( media-libs/taglib )
"
DEPEND="${RDEPEND}"
BDEPEND="doc? (
${PYTHON_DEPS}
$(python_gen_any_dep '
dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]
')
media-gfx/graphviz
)"
CONFIG_CHECK="~INOTIFY_USER"
src_configure() {
local mycmakeargs=(
-DBUILD_DOC=off
-DWITH_AVCODEC=$(usex ffmpeg)
-DWITH_CURL=$(usex curl)
-DWITH_DEBUG=$(usex debug)
-DWITH_EXIF=$(usex exif)
-DWITH_EXIV2=$(usex exiv2)
-DWITH_FFMPEGTHUMBNAILER=$(usex ffmpegthumbnailer)
-DWITH_INOTIFY=ON
-DWITH_JS=$(usex javascript)
-DWITH_LASTFM=OFF
-DWITH_MAGIC=$(usex magic)
-DWITH_MATROSKA=$(usex matroska)
-DWITH_MYSQL=$(usex mysql)
-DWITH_SYSTEMD=$(usex systemd)
-DWITH_TAGLIB=$(usex taglib)
)
cmake_src_configure
}
src_compile() {
cmake_src_compile
docs_compile
}
src_install() {
cmake_src_install
newinitd "${FILESDIR}"/${PN}-1.0.0.initd ${PN}
newconfd "${FILESDIR}"/${PN}-1.0.0.confd ${PN}
insinto /etc/${PN}
newins "${FILESDIR}"/${PN}-1.3.0.config config.xml
fperms 0640 /etc/${PN}/config.xml
fowners root:gerbera /etc/${PN}/config.xml
}
pkg_postinst() {
if use mysql; then
elog "Gerbera has been built with MySQL support and needs"
elog "to be configured before being started. By default"
elog "SQLite will be used."
fi
}
|
GitWeb