blob: 135c195e304e5155f58de1c5cea8b0b5bd201df5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit autotools eutils systemd vcs-snapshot user
DESCRIPTION="Update local time over HTTPS"
HOMEPAGE="https://github.com/ioerror/tlsdate"
SRC_URI="https://github.com/ioerror/tlsdate/tarball/${P} -> ${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="amd64 arm arm64 hppa ia64 m68k ~mips s390 sh sparc x86"
IUSE="dbus +seccomp static-libs"
DEPEND="dev-libs/openssl:0=
dev-libs/libevent:=
dbus? ( sys-apps/dbus )"
RDEPEND="${DEPEND}"
PATCHES=(
"${FILESDIR}"/${P}-tlsdated-service.patch
)
src_prepare() {
# Use the system cert store rather than a custom one specific
# to the tlsdate package. #534394
sed -i \
-e 's:/tlsdate/ca-roots/tlsdate-ca-roots.conf:/ssl/certs/ca-certificates.crt:' \
Makefile.am || die
default
eautoreconf
}
src_configure() {
econf \
--disable-silent-rules \
$(use_enable dbus) \
$(use_enable seccomp seccomp-filter) \
--disable-hardened-checks \
--without-polarssl \
--with-unpriv-user=tlsdate \
--with-unpriv-group=tlsdate
}
src_install() {
default
# Use the system cert store; see src_prepare. #446426 #534394
rm "${ED}"/etc/tlsdate/ca-roots/tlsdate-ca-roots.conf || die
rmdir "${ED}"/etc/tlsdate/ca-roots || die
newinitd "${FILESDIR}"/tlsdated.rc tlsdated
newconfd "${FILESDIR}"/tlsdated.confd tlsdated
newinitd "${FILESDIR}"/tlsdate.rc tlsdate
newconfd "${FILESDIR}"/tlsdate.confd tlsdate
systemd_newunit "${S}"/systemd/tlsdated.service tlsdated.service
systemd_newtmpfilesd "${FILESDIR}"/tlsdated.tmpfiles.conf tlsdated.conf
insinto /etc/default
newins "${FILESDIR}"/tlsdated.default tlsdated
insinto /etc/dbus-1/system.d/
doins dbus/org.torproject.tlsdate.conf
use static-libs || \
find "${ED}"/usr '(' -name '*.la' -o -name '*.a' ')' -delete
}
pkg_preinst() {
enewgroup tlsdate 124
enewuser tlsdate 124 -1 /dev/null tlsdate
}
|
GitWeb
