blob: 1b4f3d12d0616619e4224dab3267892dc04e2c40 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python{3_8,3_9} )
DISTUTILS_OPTIONAL="1"
inherit distutils-r1 flag-o-matic toolchain-funcs
DESCRIPTION="I2C tools for bus probing, chip dumping, EEPROM decoding, and more"
HOMEPAGE="https://www.kernel.org/pub/software/utils/i2c-tools"
SRC_URI="https://www.kernel.org/pub/software/utils/${PN}/${P}.tar.xz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
IUSE="python"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
RDEPEND="
python? ( ${PYTHON_DEPS} )"
BDEPEND="
python? (
${PYTHON_DEPS}
dev-python/setuptools[${PYTHON_USEDEP}]
)"
src_prepare() {
default
use python && distutils-r1_src_prepare
}
src_configure() {
use python && distutils-r1_src_configure
export BUILD_DYNAMIC_LIB=1
export USE_STATIC_LIB=0
export BUILD_STATIC_LIB=0
}
src_compile() {
emake AR="$(tc-getAR)" CC="$(tc-getCC)" EXTRA="eeprog"
if use python ; then
cd py-smbus || die
append-cppflags -I../include
distutils-r1_src_compile
fi
}
src_install() {
emake EXTRA="eeprog" DESTDIR="${D}" libdir="/usr/$(get_libdir)" PREFIX="/usr" install
dodoc CHANGES README
if use python ; then
cd py-smbus || die
docinto py-smbus
dodoc README*
distutils-r1_src_install
fi
}
|
GitWeb
